/*
 * Pyramid.as - Live Chroma Key ActionScript Library
 * Copyright (c) 2009 Yusuke Kawasaki http://www.kawa.net/
 *
 * Permission is hereby granted, free of charge, to any person
 * obtaining a copy of this software and associated documentation
 * files (the "Software"), to deal in the Software without
 * restriction, including without limitation the rights to use,
 * copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the
 * Software is furnished to do so, subject to the following
 * conditions:
 *
 * The above copyright notice and this permission notice shall be
 * included in all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
 * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
 * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
 * NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
 * HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
 * WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
 * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
 * OTHER DEALINGS IN THE SOFTWARE.
 *
 */

package {

    import flash.display.Sprite;
    import flash.display.Loader;
    import flash.events.Event;
	import flash.events.KeyboardEvent;
    import flash.events.MouseEvent;
    import flash.events.IOErrorEvent;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
	import flash.ui.Keyboard;

    import org.libspark.LiveChromaKey.LCK_Core;

    public class Pyramid extends Sprite {

        private var infoText:TextField;
        private var chromakey:LCK_Core;

        public function Pyramid ():void {

            // chroma key
            chromakey = new LCK_Core();
			chromakey.workX = 160;
			chromakey.workY = 120;
            chromakey.init();
            var spFore:Sprite = chromakey.getForeground();

            // background image
            var url:String = 'pyramid.jpg';
            var req:URLRequest = new URLRequest( url );
            var loader:Loader = new Loader();
            loader.addEventListener(IOErrorEvent.IO_ERROR, this.dispatchEvent);
            loader.load(req);

            // status
            infoText = this.createStatusMonitor();

            // layers
            this.addChild( loader );
            this.addChild( spFore );
            this.addChild( infoText );

            // events
            this.addEventListener( Event.ENTER_FRAME, this.onEnterFrame );
            this.addEventListener( MouseEvent.CLICK, this.onClick );
			stage.addEventListener( KeyboardEvent.KEY_DOWN, this.onKeyDown );
        }

        private function onKeyDown (e:KeyboardEvent):void {
			if ( e.keyCode == Keyboard.ESCAPE ) {
				chromakey.runDetector();
			}
        }

        private function onClick (e:Event):void {
            chromakey.runDetector();
        }

        private function createStatusMonitor ():TextField {
            var txtfmt:TextFormat = new TextFormat();
            txtfmt.font  = 'Courier New';
            txtfmt.size  = 15;
            txtfmt.color = 0x333333;
            txtfmt.bold  = true;

            var txtfield:TextField = new TextField();
            txtfield.defaultTextFormat = txtfmt;
            txtfield.autoSize = TextFieldAutoSize.LEFT;
            txtfield.multiline = true;
            txtfield.visible = false;

            return txtfield;
        }

        private function onEnterFrame (e:Event):void {
            var mStatus:String = (chromakey.getMatchLevel()*100).toFixed(2);
            var mMode:String = chromakey.ready ? '(running)' : '(preparing)';
            var str:String = mMode + '\n';
            str += 'match: '+mStatus+'%\n';
            infoText.text = str;
            infoText.visible = true;
        }
    }
}