/*
 * BetweenAS3
 * 
 * Licensed under the MIT License
 * 
 * Copyright (c) 2009 BeInteractive! (www.be-interactive.org) and
 *                    Spark project  (www.libspark.org)
 * 
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 * 
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 * 
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 * 
 */
package
{
	import flash.display.Shape;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import org.libspark.betweenas3.BetweenAS3;
	import org.libspark.betweenas3.easing.*;
	import org.libspark.betweenas3.tweens.ITween;
	
	/**
	 * @author	yossy:beinteractive
	 */
	[SWF(width = 800, height = 600, frameRate = 30, backgroundColor = 0xffffff)]
	public class EaseCustomTest extends Sprite
	{
		public function EaseCustomTest()
		{
			setupBackground();
			
			var box:Box = addChild(new Box()) as Box;
			
			_t = BetweenAS3.tween(box, {x: 700, y: 120}, {x: 100, y: 120}, 1.0, Custom.func(function(t:Number, b:Number, c:Number, d:Number):Number
			{
				// From Tweener transition example
				// http://hosted.zeh.com.br/tweener/docs/en-us/parameters/transition.html
				var ts:Number = (t /= d) * t;
				var tc:Number = ts * t;
				return b + c * (-97.1975 * tc * ts + 257.5975 * ts * ts - 234.4 * tc + 80 * ts - 5 * t);
			}));
			
			_t.play();
			
			stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler)
		}
		
		private var _t:ITween;
		
		private function setupBackground():void
		{
			var bg:Shape = new Shape();
			bg.graphics.beginFill(0xffffff);
			bg.graphics.drawRect(0, 0, 800, 600);
			bg.graphics.endFill();
			bg.graphics.beginFill(0xcccccc);
			bg.graphics.drawRect(100, 0, 1, 600);
			bg.graphics.drawRect(700, 0, 1, 600);
			bg.graphics.endFill();
			addChild(bg);
		}
		
		private function mouseDownHandler(e:MouseEvent):void
		{
			if (_t.isPlaying) {
				_t.stop();
			}
			else {
				if (_t.position == _t.duration) {
					_t.gotoAndPlay(0);
				}
				else {
					_t.play();
				}
			}
		}
	}
}

import flash.display.Shape;

internal class Box extends Shape
{
	public function Box()
	{
		graphics.beginFill(0x000000);
		graphics.drawRect(-10, -10, 20, 20);
		graphics.endFill();
	}
}