root/as3/sazameki/branches/fp10/src/samples/SineSample.as

package samples
{
    import flash.display.Sprite;
    import flash.events.SampleDataEvent;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    public class SineSample extends Sprite
    {
        private var phase:Number = 0;
        private var freq:Number = 440;
        private const PI2:Number = Math.PI * 2;
        private var soundChannelObject:SoundChannel = new SoundChannel();
        public function SineSample()
        {
            var soundObj:Sound = new Sound();
            //まずはSAMPLE_DATAイベントにリスナー登録
            soundObj.addEventListener(SampleDataEvent.SAMPLE_DATA, onSampleData);
            //mp3などの音声を割り当てずにそのままplay()で再生開始すると、
            //音のバッファが空になるたびにSAMPLE_DATAイベントが発生します。
            soundChannelObject = soundObj.play();
        }
        private function onSampleData(e:SampleDataEvent):void
        {
            var smpl:Number;
            var w:Number = PI2 * freq / 44100;
            
            //レイテンシの計測【※１】
            var latency:Number = e.position / 44.1 - soundChannelObject.position;

            //一度のイベントごとに2048～8192サンプル×左右2チャンネル分のデータを書き込みます。
            for (var i:int = 0; i < 4096; ++i) {
                //波形データを生成【※２】
                phase += w;
                if (phase > PI2) {
                    phase -= PI2;
                }
                smpl = Math.sin(phase);
                
                //SampleDataEvent.dataにwriteFloat()で波形データを書き込む【※２】
                e.data.writeFloat(smpl);
                e.data.writeFloat(smpl);
            }
        }
    }
}