root/as3/sazameki/branches/fp10/src/samples/SimpleSoundSample.as

package samples 
{
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.events.SampleDataEvent;
        import flash.media.Sound;
        
        public class SimpleSoundSample extends Sprite
        {
                [Embed(source = 'asset/movemouse.png')]
                private var bg:Class;
                private var phase:Number = 0;
                private var frequency:Number = 440;
                private var shapeFactor:Number = 0;
                
                public function SimpleSoundSample()
                {
                        //Soundインスタンスを作る
                        var sound:Sound = new Sound();
                        //SAMPLE_DATAイベントにリスナー登録
                        sound.addEventListener(SampleDataEvent.SAMPLE_DATA, onSampleData);
                        //再生開始する
                        sound.play();
                        
                        addEventListener(Event.ENTER_FRAME, onMouseMove);
                        addChild(new bg());
                }
        
                private function onSampleData(e:SampleDataEvent):void{
                        var sig:Number;
                        
                        for (var i:int = 0; i < 2048; ++i )
                        {
                                sig = getCurrentData()*0.8;
                                //SampleDataEvent.dataに波形データを書き込む（-1.0～1.0のNumber）
                                //左チャンネル
                                e.data.writeFloat(sig);
                                //右チャンネル
                                e.data.writeFloat(sig);
                        }
                }
                
                private var pi2:Number = Math.PI * 2;
                private function getCurrentData():Number
                {
                        phase += frequency * pi2 / 44100;
                        if (phase > pi2) phase -= pi2;
                        return (Math.sin(phase)*shapeFactor + (phase < Math.PI ? 1:-1 )*(1-shapeFactor)*0.5);
                }
                
                private function onMouseMove(e:Event):void{
                        frequency = mouseY*2  + 55;
                        shapeFactor = 1-mouseX/stage.stageWidth;
                }
        }
        
}