root/as3/sazameki/branches/fp10/src/samples/SamplerSample.as

package samples 
{
        import flash.display.DisplayObject;
        import flash.display.Sprite;
        import flash.display.StageAlign;
        import flash.display.StageScaleMode;
        import flash.events.Event;
        import flash.events.SampleDataEvent;
        import flash.media.Sound;
        import flash.sampler.Sample;
        import flash.utils.ByteArray;
        import org.sazameki.audio.core.AudioSamples;
        import org.sazameki.audio.core.AudioSetting;
        import org.sazameki.audio.ctrlEvent.events.NoteOff;
        import org.sazameki.audio.ctrlEvent.events.NoteOn;
        import org.sazameki.audio.engine.MultiSamplePlayer.Instrument;
        import org.sazameki.audio.engine.MultiSamplePlayer.MultiSamplePlayer;
        import org.sazameki.audio.engine.MultiSamplePlayer.NoteRange;
        import org.sazameki.audio.engine.MultiSamplePlayer.ProcessData;
        import org.sazameki.audio.format.wav.Wav;
        import org.sazameki.events.NoteEvent;
        import org.sazameki.ui.KeyboardKeyboard;
        
        /**
        * ...
        * @author Takaaki Yamazaki(zk design)
        */
        public class SamplerSample extends Sprite
        {
                [Embed(source = "asset/bass_c2_9836_10510.wav", mimeType = "application/octet-stream")]
                public const Bass:Class;

                [Embed(source = "asset/Clap.wav", mimeType = "application/octet-stream")]
                public const Clap:Class;
                [Embed(source = "asset/Hat.wav", mimeType = "application/octet-stream")]
                public const Hat:Class;
                [Embed(source = "asset/Kick.wav", mimeType = "application/octet-stream")]
                public const Kick:Class;
                [Embed(source = "asset/Snare.wav", mimeType = "application/octet-stream")]
                public const Snare:Class;

                [Embed(source = "asset/synth.png")]
                public const Img:Class;
                
                private var sampler:MultiSamplePlayer;
                private var sound:Sound;
                private var procData:ProcessData;
                public function SamplerSample() 
                {
                        stage.scaleMode = StageScaleMode.NO_SCALE;
                        
                        var img:DisplayObject = new Img();
                        addChild(img);
                        
                        var keyboard:KeyboardKeyboard = new KeyboardKeyboard(stage,1);
                        keyboard.addEventListener(NoteEvent.NOTE_ON, onNoteOn);
                        keyboard.addEventListener(NoteEvent.NOTE_OFF, onNoteOff);
                        
                        var decoder:Wav = new Wav();

                        var bassSamples:AudioSamples = decoder.decode(new Bass() as ByteArray);
                        var bassInst:Instrument = new Instrument(bassSamples, 9836, 10509, 24);
                        
                        var clapSamples:AudioSamples = decoder.decode(new Clap() as ByteArray);
                        var clapInst:Instrument = new Instrument(clapSamples);
                        
                        var hatSamples:AudioSamples = decoder.decode(new Hat() as ByteArray);
                        var hatInst:Instrument = new Instrument(hatSamples);
                        
                        var kickSamples:AudioSamples = decoder.decode(new Kick() as ByteArray);
                        var kickInst:Instrument = new Instrument(kickSamples);
                        
                        var snareSamples:AudioSamples = decoder.decode(new Snare() as ByteArray);
                        var snareInst:Instrument = new Instrument(snareSamples);
                        
                        sampler = new MultiSamplePlayer();
                        sampler.addInstrument(bassInst, new NoteRange(24));
                        sampler.addInstrument(kickInst, new NoteRange(0, 13));
                        sampler.addInstrument(hatInst, new NoteRange(18, 23));
                        sampler.addInstrument(clapInst, new NoteRange(14, 15));
                        sampler.addInstrument(snareInst, new NoteRange(16, 17));
                        //prepare processData(sample buffer & event list)
                        procData = new ProcessData(2048);
                        
                        //prepare sound
                        sound = new Sound();
                        sound.addEventListener(SampleDataEvent.SAMPLE_DATA, onSamplesCallback);
                        sound.play();
                }               
                private function onNoteOn(e:NoteEvent):void 
                {
                        procData.events.addEvent(new NoteOn(e.note), 0);
                }
                private function onNoteOff(e:NoteEvent):void 
                {
                        procData.events.addEvent(new NoteOff(e.note), 0);
                }
                private function onSamplesCallback(e:SampleDataEvent):void 
                {

                        
                        var left:Vector.<Number>;
                        var right:Vector.<Number>;
                        
                        var audios:AudioSamples = procData.samples;
                        
                        var len:int = procData.length;
                
                        var i:int = 0;
                        var sig:Number;
                        
                        sampler.process(procData);
                        
                        if (audios.setting.channels == 2)
                        {
                                left = audios.left;
                                right = audios.right;
                                for (; i < len; ++i)
                                {
                                        e.data.writeFloat(left[i]);
                                        e.data.writeFloat(right[i]);
                                
                                }
                        }else
                        {
                                left = audios.left;
                                for (; i < len; ++i)
                                {
                                        sig = left[i];
                                        e.data.writeFloat(sig);
                                        e.data.writeFloat(sig);
                                }
                                
                        }
                }
                
        }
        
}