root/as3/gunyarapaint/trunk/src/main.as

import flash.events.Event;

import gunyarapaint.Canvas;
import gunyarapaint.Com;

import mx.events.ColorPickerEvent;
import mx.events.FlexEvent;
import mx.events.ListEvent;
import mx.events.NumericStepperEvent;
import mx.events.SliderEvent;
import mx.managers.PopUpManager;

private var gpCanvas:gunyarapaint.Canvas;
private const CANVAS_WIDTH:uint = 400;
private const CANVAS_HEIGHT:uint = 300;
private var basex:uint, basey:uint;
private var appWidth:uint, appHeight:uint;

public function init():void {  
  gpCanvas = new gunyarapaint.Canvas(CANVAS_WIDTH, CANVAS_HEIGHT, 12);
  // gpCanvas.scrollRect = new Rectangle(0, 0, 300, 300);
  canvas.addChild(gpCanvas);
  gpCanvas.rotation = 0; //. うひひ
  
  // 太さ
  thicknessStepper.addEventListener(NumericStepperEvent.CHANGE, thicknessStepperHandler);
  // カラーピッカ
  colorPicker.addEventListener(ColorPickerEvent.CHANGE, colorPickerHandler);
  // スポイト
  dropperButton.addEventListener(Event.CHANGE, dropperButtonHandler);
  // 透明度
  alphaSlider.addEventListener(SliderEvent.CHANGE, alphaSliderHandler);
  // キャンバス回転
  canvasRotate.addEventListener(SliderEvent.CHANGE, canvasRotateHandler);
  canvasRotate.addEventListener(SliderEvent.THUMB_DRAG, canvasRotateHandler);
  // 回転のときに勝手にApplicationの領域が拡大しないように
  canvas.explicitWidth = 0;
  canvas.explicitHeight = 0;
  
  // ブレンドモード
  blendModeComboBox.dataProvider = [
    {label: '通常', data: flash.display.BlendMode.NORMAL},
    // {label: '消去', data: flash.display.BlendMode.ERASE},
    {label: '比較(暗)', data: flash.display.BlendMode.DARKEN},
    {label: '乗算', data: flash.display.BlendMode.MULTIPLY},
    {label: '比較(明)', data: flash.display.BlendMode.LIGHTEN},
    {label: 'スクリーン', data: flash.display.BlendMode.SCREEN},
    {label: '覆い焼き', data: flash.display.BlendMode.ADD},
    {label: 'オーバーレイ', data: flash.display.BlendMode.OVERLAY},
    {label: 'ハードライト', data: flash.display.BlendMode.HARDLIGHT},
    {label: '差の絶対値', data: flash.display.BlendMode.DIFFERENCE},
    {label: '除外', data: flash.display.BlendMode.SUBTRACT},
    {label: '反転', data: flash.display.BlendMode.INVERT}];
  blendModeComboBox.addEventListener(ListEvent.CHANGE, blendModeComboBoxHandler);
  
  // アンドゥ・リドゥ
  undoButton.addEventListener(FlexEvent.BUTTON_DOWN, undoButtonHandler);
  redoButton.addEventListener(FlexEvent.BUTTON_DOWN, redoButtonHandler);
   
  // 補助線
  additionalNumberStepper.addEventListener(NumericStepperEvent.CHANGE, additionalNumberStepperHandler);
  additionalBoxCheckBox.addEventListener(Event.CHANGE, additionalBoxCheckBoxHandler);
  additionalSkewCheckBox.addEventListener(Event.CHANGE, additionalSkewCheckBoxHandler);
  // スポイトで色取ったイベント
  gpCanvas.addEventListener('changeColor', changeColorHandler);
  // undo/redoの状態変化
  gpCanvas.addEventListener('changeUndoRedo', changeUndoRedoHandler);
  
  postOekakiButton.addEventListener(FlexEvent.BUTTON_DOWN, postOekakiButtonHandler);
  
  // いろんな初期値を保存…
  basex = canvas.x;
  basey = canvas.y;
  
  appWidth = this.width;
  appHeight = this.height;
}

private function thicknessStepperHandler(evt:NumericStepperEvent):void {
  gpCanvas.setLineThickness(evt.value);
}

private function colorPickerHandler(evt:ColorPickerEvent):void {
  gpCanvas.setLineColor(evt.target.selectedColor);
}

private function alphaSliderHandler(evt:SliderEvent):void {
  gpCanvas.setLineAlpha(evt.value);
}

private function canvasRotateHandler(evt:SliderEvent):void {
  var deg:int = evt.value;
  var rad:Number = deg * Math.PI / 180;
  // TODO: dasai
  if (deg >= 0) {
    if (deg <= 90) {
      canvas.x = basex + Math.sin(rad) * CANVAS_HEIGHT;
      canvas.y = basey
    } else {
      // FIXME: implement
    }
  } else {
    if (deg >= -90) {
      canvas.x = basex;
      canvas.y = basey - Math.sin(rad) * CANVAS_WIDTH;
    } else {
      // FIXME: implement
    }
  }
  gpCanvas.rotation = evt.value;
  this.height = CANVAS_HEIGHT * (Math.cos(rad) - 1) +
                CANVAS_WIDTH * Math.abs(Math.sin(rad)) + appHeight;
}

private function blendModeComboBoxHandler(evt:ListEvent):void {
  gpCanvas.setLineBlendMode(String(evt.currentTarget.value));
}
private function undoButtonHandler(evt:FlexEvent):void {
  gpCanvas.undo();
}
private function redoButtonHandler(evt:FlexEvent):void {
  gpCanvas.redo();
}
private function dropperButtonHandler(evt:Event):void {
  if (evt.target.selected) {
    gpCanvas.setPenMode(gpCanvas.MODE_DROPPER);    
  } else {
    gpCanvas.setPenMode(gpCanvas.MODE_PEN);
  }
}
private function changeColorHandler(evt:Event):void {
  colorPicker.selectedColor = gpCanvas.getLineColor();
  alphaSlider.value = 1.0;
}
private function additionalNumberStepperHandler(evt:NumericStepperEvent):void {
  gpCanvas.setAdditionalNumber(evt.value);
}
private function additionalBoxCheckBoxHandler(evt:Event):void {
  gpCanvas.setAdditionalBox(evt.target.selected);
}
private function additionalSkewCheckBoxHandler(evt:Event):void {
  gpCanvas.setAdditionalSkew(evt.target.selected);
}
private function changeUndoRedoHandler(evt:Event):void {
  var undoCount:Number = gpCanvas.getUndoCount();
  var redoCount:Number = gpCanvas.getRedoCount();
  if (undoCount > 0) {
    undoButton.label = 'アンドゥ (' + undoCount + ')';
    undoButton.enabled = true;
  } else {
    undoButton.label = 'アンドゥ';
    undoButton.enabled = false;
  }
  if (redoCount > 0) {
    redoButton.label = 'リドゥ (' + redoCount + ')';
    redoButton.enabled = true;
  } else {
    redoButton.label = 'リドゥ';
    redoButton.enabled = false;
  }
}

private function postOekakiButtonHandler(evt:Event):void { 
}