root/as3/gunyarapaint/trunk/picokakiko/src/picokakiko.as

import flash.events.Event;

import gunyarapaint.Com;

import mx.controls.Alert;
import mx.events.FlexEvent;

private var comm:Com;
private var mmlId:uint;
private var played:Boolean = false;
private var poster:Boolean = false;
private var redirectUrl:String;
private const ALERT_TITLE:String = 'ピコカキコ';

private var onPost:Boolean = false;

public function init():void {
  comm = new Com;
  comm.addEventListener('completeGetData', commCompleteHandler);
  if (parameters['mmlUrl']) {
    var url:String = parameters['mmlUrl'];
    comm.sendGetUrlRequest(url);
    mml.enabled = false;
  }
  if (parameters['postUrl'] && parameters['cookie'] && parameters['magic']) {
    comm.setPostEnv(parameters['postUrl'], parameters['cookie'], parameters['magic']);
    postPicoButton.enabled = true;
  }
  if (parameters['redirectUrl']) {
    redirectUrl = parameters['redirectUrl'];
  }
  if (parameters['mmlId']) {
    mmlId = uint(parameters['mmlId']);
  }
  mml_player.addEventListener('compileComplete', playerCompileCompleteHandler);

  playButton.addEventListener(FlexEvent.BUTTON_DOWN, playButtonHandler);
  stopButton.addEventListener(FlexEvent.BUTTON_DOWN, stopButtonHandler);
  postPicoButton.addEventListener(FlexEvent.BUTTON_DOWN, postPicoButtonHandler);
}

private function playerCompileCompleteHandler(evt:Event):void {
  mml_warnings.text = mml_player.getWarnings();
  stopButton.enabled = true;
  played = true;
}

private function commCompleteHandler(evt:Event):void {
  if (onPost) {
    onPost = false;
    if (comm.getHttpStatus() == 400 || comm.getError()) {
      // error
      Alert.show(comm.getStringData(), ALERT_TITLE);
      postPicoButton.enabled = true;    
    } else {
      // redirect
      Com.redirect(redirectUrl);
    }
  } else {
    mml.text = comm.getStringData();
    mml.enabled = true;
    playButton.enabled = true;
  }
}

private function playButtonHandler(evt:Event):void {
  playButton.enabled = false;
  mml_player.play(mml.text);
}

private function stopButtonHandler(evt:Event):void {
  mml_player.stop();
  playButton.enabled = true;
  stopButton.enabled = false;
}

private function postPicoButtonHandler(evt:Event):void {
  if (messageTextArea.text == '') {
    Alert.show('書き込みが空です。曲のタイトルなどの情報を書き込んでください。', ALERT_TITLE);
    return;      
  }
  if (mml.text == '') {
    Alert.show('ピコ文字が空です。ピコピコしてください。', ALERT_TITLE);
    return;
  }
  if (!played) {
    Alert.show('投稿するためには、１回再生することが必要です。', ALERT_TITLE);
    return;
  }
  if (mml_player.getWarnings() != '') {
    Alert.show('投稿するためには、ピコ警告を全て取り除くことが必要です。', ALERT_TITLE);
    return;
  }
  postPicoButton.enabled = false;
  onPost = true;
  comm.postPico(fromTextInput.text, messageTextArea.text, mml.text, mmlId);
}