root/as3/gunyarapaint/trunk/nicopedia/gunyarapaint/Com.as

package gunyarapaint
{
  import flash.display.DisplayObject;
  
  import mx.core.UIComponent;
  
  public class Com extends UIComponent
  {
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.events.ProgressEvent;
    import flash.events.SecurityErrorEvent;
    import flash.utils.ByteArray;
    import flash.events.HTTPStatusEvent;
    import flash.events.IEventDispatcher;
    import flash.display.Loader;
    import flash.net.*;
    
    import mx.controls.Alert;
    
    import mx.managers.PopUpManager;
    
    private const ALERT_TITLE:String = 'ニコニコ大百科伝言班';
    
    private var postUrl:String;
    private var cookie:String;
    private var magic:String;
  
    private var urlLoader:URLLoader;
    private var loader:Loader;
    
    private var errorStr:String;

    public function Com()
    {
    }

    public function setPostEnv(postUrl:String, cookie:String, magic:String):void {
      this.postUrl = postUrl;
      this.cookie = cookie;
      this.magic = magic;
    }
    
    public function postPico(name:String, msg:String, mml:String, ref_mml_id:uint):void {
      var r:URLRequest = new URLRequest();
      var v:URLVariables = new URLVariables();
      r.url = postUrl;
      r.method = URLRequestMethod.POST;
      r.data = v;
      v.magic = magic;
      v.FROM = name;
      v.MESSAGE = msg;
      v.MML = mml;
      v.ref_mml_id = ref_mml_id;
      v.cookie = cookie;
      
      post(r);
    }
    
    public static function redirect(url:String):void {
      var r:URLRequest = new URLRequest();
      r.url = url;
      r.method = URLRequestMethod.GET;
      navigateToURL(r, '_top');
    }
    
    public static function redirectPicoForm(url:String, mml_id:uint):void {
      var r:URLRequest = new URLRequest();
      var v:URLVariables = new URLVariables();
      r.url = url;
      r.data = v;
      r.method = URLRequestMethod.POST;
      v.mml_id = mml_id;
      
      navigateToURL(r, '_top');
    }
    
    public function postOekaki(name:String, msg:String,
                                 image:ByteArray, log:ByteArray, ref_oekaki_id:uint):void {
      var r:URLRequest = new URLRequest();
      var v:URLVariables = new URLVariables();
      var b:ByteArray = new ByteArray();
      
      v.cookie = cookie;
      v.magic = magic;
      v.FROM = name;
      v.MESSAGE = msg;
      v.ref_oekaki_id = ref_oekaki_id;
      var form:String = v.toString();
      b.writeUTFBytes(':' + form.length + '=' + form);
      b.writeUTFBytes('&IMAGE:' + image.length + '=');
      b.writeBytes(image);
      b.writeUTFBytes('&IMAGE_LOG:' + log.length + '=');
      b.writeBytes(log);
      r.url = postUrl;
      r.method = URLRequestMethod.POST;    
      r.contentType = 'application/x-nicopedia-oekaki';
      r.data = b;
      
      post(r);
    }
    
    public static function navigate(url:String, target:String):void {
      var r:URLRequest = new URLRequest();
      r.url = url;
      r.method = URLRequestMethod.POST;
      navigateToURL(r, target);
    }
    
    public function sendGetUrlRequest(url:String):void {
      var r:URLRequest = new URLRequest();
      r.url = url;
      r.method = URLRequestMethod.GET;
      post(r);
    }
    
    private function post(request:URLRequest):void {
      errorStr = null;
      urlLoader = new URLLoader();
      urlLoader.dataFormat = URLLoaderDataFormat.BINARY;
      configureListeners(urlLoader);
      urlLoader.load(request);
    }

    public function loadUrl(url:String):void {
      var r:URLRequest = new URLRequest();
      r.url = url;
      r.method = URLRequestMethod.GET;
      load(r);
    }

    public function load(request:URLRequest):void {
      loader = new Loader();
      configureListeners(loader.contentLoaderInfo);
      loader.load(request);
    }
    
    private function configureListeners(dispatcher:IEventDispatcher):void {
      // dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, postHttpStatusHandler);
      dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, postSecurityErrorHandler);
      dispatcher.addEventListener(IOErrorEvent.IO_ERROR, postIOErrorHandler);
      dispatcher.addEventListener(Event.OPEN, postOpenHandler);
      dispatcher.addEventListener(ProgressEvent.PROGRESS, postProgressHandler);
      dispatcher.addEventListener(Event.COMPLETE, postCompleteHandler);            
    }
    
    private function postSecurityErrorHandler(evt:SecurityErrorEvent):void {
      errorStr = 'セキュリティエラーが発生しました。\n詳細:' + evt.text;
      dispatchEvent(new Event('completeGetData'));
    }
    private function postIOErrorHandler(evt:IOErrorEvent):void {
      // TODO: not event based, see URLLoader help
      errorStr = 'ネットワークエラーが発生しました。\n詳細:' + evt.text;
      dispatchEvent(new Event('completeGetData'));
    }
    private function postOpenHandler(evt:Event):void {
    }
    private function postProgressHandler(evt:ProgressEvent):void {
      evt.bytesLoaded + evt.bytesTotal;
    }
    private function postCompleteHandler(evt:Event):void {
      dispatchEvent(new Event('completeGetData'));
    }
    public function getData():ByteArray {
      return urlLoader.data;
    }
    public function getStringData():String {
      return urlLoader.data.toString();
    }
    public function getContent():DisplayObject {
      return loader.content;
    }
    public function getErrorStr():String {
      return errorStr;
    }
  }
}