root/as3/gunyarapaint/trunk/gunyarapaint/src/org/libspark/gunyarapaint/controls/GPCanvasWindowControl.as

package org.libspark.gunyarapaint.controls
{
  import flash.events.Event;
  import flash.events.MouseEvent;
  import flash.geom.Point;
  
  import mx.containers.HBox;
  import mx.containers.TitleWindow;
  import mx.containers.VBox;
  import mx.controls.HScrollBar;
  import mx.controls.VScrollBar;
  import mx.controls.scrollClasses.ScrollBar;
  import mx.core.Container;
  import mx.events.MoveEvent;
  import mx.events.ResizeEvent;
  import mx.events.ScrollEvent;
  import mx.utils.ColorUtil;
  
  import org.libspark.gunyarapaint.entities.GPLogger;
  import org.libspark.gunyarapaint.utils.ComponentResizer;

  public class GPCanvasWindowControl extends TitleWindow
  {
    private var _canvasContainer:Container; // GPCanvasを直接格納するコンテナ
    private var _contentContainer:Container; // GPCanvasとその周りの背景を格納するコンテナ
    
    private var _hbox:HBox; // canvasと縦スクロールバー
    private var _vbox:VBox; // _hboxと横スクロールバー
    
    private var hScrollBar:HScrollBar; // 横スクロールバー
    private var vScrollBar:VScrollBar; // 縦スクロールバー
    private var canvasX:Number, canvasY:Number; // キャンバスのスクロール位置
    private var _canvasScale:Number; // キャンバスの倍率

    private var _logger:GPLogger;

    public function GPCanvasWindowControl() {
      super();
      
      this.backgroundColor = 0x000000;

      // this.setStyle('backgroundAlpha', 0);
      this.horizontalScrollPolicy = 'off';
      this.verticalScrollPolicy = 'off';

      this.addEventListener(ResizeEvent.RESIZE, resizeHandler);
      this.addEventListener(MoveEvent.MOVE, moveHandler);

      ComponentResizer.addResize(this, new Point(100, 100));
    }

    private function set backgroundColor(c:uint):void {
      this.setStyle('backgroundColor', c);      
    }

    private function contentContainerClickHandler(e:MouseEvent):void {
      if (e.eventPhase == flash.events.EventPhase.AT_TARGET) {
        this.backgroundColor = Math.random() * 0xffffff;
      }
    }

    private function resizeContainer():void {
      if (_logger && _canvasContainer && _contentContainer) {
        // 仮にサイズを狭める
        _canvasContainer.width = _canvasContainer.height = 
          _contentContainer.width = _contentContainer.height = 
          hScrollBar.width = vScrollBar.height = 0;
        
        this.validateNow(); // _vbox/_hboxのサイズを更新
  
        // それを使って再設定
        var clientWidth:Number = _hbox.width - vScrollBar.width;
        var clientHeight:Number = _vbox.height - hScrollBar.height;
        var frameWidth:Number = this.width - _hbox.width;
        var frameHeight:Number = this.height - _vbox.height;

        _contentContainer.width = _contentContainer.maxWidth = clientWidth;
        _contentContainer.height = _contentContainer.maxHeight = clientHeight;
        this.width = clientWidth + vScrollBar.width + frameWidth;
        this.height = clientHeight + hScrollBar.height + frameHeight;
        hScrollBar.width = clientWidth;
        vScrollBar.height = clientHeight;
        // TODO: minでいいやん
        if (_logger.canvasWidth * _canvasScale < clientWidth) {
          _canvasContainer.width = _logger.canvasWidth * _canvasScale;
        } else {
          _canvasContainer.width = clientWidth;
        }
        if (_logger.canvasHeight * _canvasScale < clientHeight) {
          _canvasContainer.height = _logger.canvasHeight * _canvasScale;
        } else {
          _canvasContainer.height = clientHeight;          
        }
        _canvasContainer.move((_contentContainer.width - _canvasContainer.width) / 2,
                              (_contentContainer.height - _canvasContainer.height) / 2);
      }
    }
    
    private function resizeHandler(evt:ResizeEvent):void {
      resizeContainer();
      moveCanvas();
    }
    
    private function moveHandler(evt:MoveEvent):void {
      // 整数化して、shape->bitmapのズレをなくす
      this.x = int(x);
      this.y = int(y);
    }
    
    private var scrollDragStartPoint:Point;
    
    public function set logger(log:GPLogger):void {    
      if (!_logger) {
        _logger = log;
        //_canvas.setStyle('borderColor', 0x000000);
        //_canvas.setStyle('borderStyle', 'solid');
        //_canvas.setStyle('borderThickness', 1);        

        _vbox = new VBox();
        _vbox.percentWidth = 100;
        _vbox.percentHeight = 100;
        _vbox.setStyle('verticalGap', 0);
        _hbox = new HBox();
        _hbox.percentWidth = 100;
        _hbox.percentHeight = 100;
        _hbox.setStyle('horizontalGap', 0);
        _vbox.addChild(_hbox);
        this.addChild(_vbox);
        
        this.validateNow(); // percentWidth/Height -> width/heightに更新

        _contentContainer = new Container();
        _contentContainer.setStyle('borderStyle', 'none');
        _contentContainer.horizontalScrollPolicy = 'off';
        _contentContainer.verticalScrollPolicy = 'off';

        _canvasContainer = new Container();
        _canvasContainer.setStyle('borderStyle', 'none');
        _canvasContainer.horizontalScrollPolicy = 'off';
        _canvasContainer.verticalScrollPolicy = 'off';

        hScrollBar = new HScrollBar();
        vScrollBar = new VScrollBar();
        hScrollBar.height = ScrollBar.THICKNESS;
        vScrollBar.width = ScrollBar.THICKNESS;
        hScrollBar.move(0, height);
        vScrollBar.move(width, 0);
        hScrollBar.addEventListener(ScrollEvent.SCROLL, hScrollHandler);
        vScrollBar.addEventListener(ScrollEvent.SCROLL, vScrollHandler);
        hScrollBar.lineScrollSize = 1;
        vScrollBar.lineScrollSize = 1;
        
        _canvasContainer.addChild(log.canvas);
        _contentContainer.addChild(_canvasContainer);
        _hbox.addChild(_contentContainer);
        _hbox.addChild(vScrollBar);
        _vbox.addChild(hScrollBar);

        _contentContainer.addEventListener(MouseEvent.CLICK, contentContainerClickHandler);

        canvasX = 0; canvasY = 0; _canvasScale = 1;
        resizeContainer();
        moveCanvas();
      }
    }

    private function moveCanvas():void {
      if (_logger && _canvasContainer && _contentContainer) {
        var maxX:Number = _logger.canvasWidth * _canvasScale - _canvasContainer.width;
        var maxY:Number = _logger.canvasHeight * _canvasScale - _canvasContainer.height;
        canvasX = Math.floor(canvasX);
        canvasY = Math.floor(canvasY);
        if (maxX <= 0) maxX = 0;
        if (maxY <= 0) maxY = 0;
        if (canvasX < 0) { canvasX = 0; }
        if (canvasY < 0) { canvasY = 0; }
        if (canvasX > maxX) { canvasX = maxX; }
        if (canvasY > maxY) { canvasY = maxY; }
        hScrollBar.scrollPosition = canvasX;
        vScrollBar.scrollPosition = canvasY;
        hScrollBar.setScrollProperties(_contentContainer.width * _canvasScale, 0, maxX, _canvasScale);
        vScrollBar.setScrollProperties(_contentContainer.height * _canvasScale, 0, maxY, _canvasScale);
        _logger.eventCanvasMove(-canvasX, -canvasY);
      }
    }
    
    private function hScrollHandler(evt:ScrollEvent):void {
      canvasX = hScrollBar.scrollPosition;
      moveCanvas();
    }

    private function vScrollHandler(evt:ScrollEvent):void {
      canvasY = vScrollBar.scrollPosition;
      moveCanvas();
    }
    public function scrollCanvas(x:Number, y:Number):void {
      canvasX = x; canvasY = y;
      moveCanvas();
    }
    
    public function get canvasScrollPosition():Point {
      return new Point(canvasX, canvasY);
    }
    
    public function get canvasScale():Number {
      return _canvasScale;
    }

    public function set statusText(value:String):void {
      this.status = value;
    }

    public function zoomCanvas(m:Number):void {
      var rm:Number;
      if (m >= 1) {
        rm = m;
      } else {
        rm = 1.0 / (-m + 2);
      }
      _canvasScale = rm;
      _logger.eventCanvasScale(rm);
      resizeContainer();
      moveCanvas();
    }
    
    public function rotateCanvas(deg:int):void {
      this.rotation = deg;
    }
 }
}