root/as3/gunyarapaint/trunk/gunyarapaint/src/org/libspark/gunyarapaint/controls/GPCanvasWindowControl.as

package org.libspark.gunyarapaint.controls
{
  import flash.display.BitmapData;
  import flash.geom.Point;
  
  import org.libspark.gunyarapaint.entities.GPLogger;
  import org.libspark.gunyarapaint.entities.GPPen;
  import org.libspark.gunyarapaint.utils.ComponentResizer;
  
  import mx.containers.HBox;
  import mx.containers.TitleWindow;
  import mx.containers.VBox;
  import mx.controls.HScrollBar;
  import mx.controls.VScrollBar;
  import mx.controls.scrollClasses.ScrollBar;
  import mx.core.Container;
  import mx.events.ResizeEvent;
  import mx.events.ScrollEvent;

  public class GPCanvasWindowControl extends TitleWindow
  {
    private var _canvas:GPCanvas;
    private var _container:Container;
    
    private var _hbox:HBox; // canvasと縦スクロールバー
    private var _vbox:VBox; // _hboxと横スクロールバー
    
    private var hScrollBar:HScrollBar; // 横スクロールバー
    private var vScrollBar:VScrollBar; // 縦スクロールバー
    private var canvasX:Number, canvasY:Number; // キャンバスのスクロール位置
    private var _canvasScale:Number; // キャンバスの倍率

    public function GPCanvasWindowControl() {
      super();

      this.setStyle('backgroundColor', 0x000000);
      // this.setStyle('backgroundAlpha', 0);
      this.horizontalScrollPolicy = 'off';
      this.verticalScrollPolicy = 'off';

      this.addEventListener(ResizeEvent.RESIZE, resizeHandler);

      ComponentResizer.addResize(this, new Point(100, 100));
    }
    
    private function resizeHandler(evt:ResizeEvent):void {
      // スクロールバー

      /*
      if (_canvas) {
        _canvas.changeCanvasWindowSize(this.width, this.height);
      }
      */
    }
    
    private var scrollDragStartPoint:Point;
    
    public function createCanvas(width:uint, height:uint, undoBufferSize:uint, logger:GPLogger, baseData:BitmapData, penDetailWindow:PenDetailWindowControl):GPCanvas {
      if (!_canvas) {
        _canvas = new GPCanvas(width, height, undoBufferSize, logger, baseData, penDetailWindow);
        //_canvas.setStyle('borderColor', 0x000000);
        //_canvas.setStyle('borderStyle', 'solid');
        //_canvas.setStyle('borderThickness', 1);        

        _vbox = new VBox();
        _vbox.percentWidth = 100;
        _vbox.percentHeight = 100;
        _vbox.setStyle('verticalGap', 0);
        _hbox = new HBox();
        _hbox.percentWidth = 100;
        _hbox.percentHeight = 100;
        _hbox.setStyle('horizontalGap', 0);
        _vbox.addChild(_hbox);
        this.addChild(_vbox);
        
        this.validateNow(); // percentWidth/Height -> width/heightに更新

        _container = new Container();
        _container.setStyle('borderStyle', 'none');
        _container.horizontalScrollPolicy = 'off';
        _container.verticalScrollPolicy = 'off';

        hScrollBar = new HScrollBar();
        vScrollBar = new VScrollBar();
        hScrollBar.height = ScrollBar.THICKNESS;
        vScrollBar.width = ScrollBar.THICKNESS;
        hScrollBar.move(0, height);
        vScrollBar.move(width, 0);
        hScrollBar.addEventListener(ScrollEvent.SCROLL, hScrollHandler);
        vScrollBar.addEventListener(ScrollEvent.SCROLL, vScrollHandler);
        hScrollBar.lineScrollSize = 1;
        vScrollBar.lineScrollSize = 1;

        _container.addChild(_canvas);
        _hbox.addChild(_container);
        _hbox.addChild(vScrollBar);
        _vbox.addChild(hScrollBar);

        _container.width = _container.maxWidth = _hbox.width - vScrollBar.width;
        _container.height = _container.maxHeight = _vbox.height - hScrollBar.height;
        hScrollBar.width = _container.width;
        vScrollBar.height = _container.height;

        _canvas.canvasWindowControl = this;

        canvasX = 0; canvasY = 0; _canvasScale = 1;
        moveCanvas();
      }
      return _canvas;
    }

    private function moveCanvas():void {
      var maxX:Number = Math.floor(_canvas.canvasWidth - (_container.width / _canvasScale));
      var maxY:Number = Math.floor(_canvas.canvasHeight - (_container.height / _canvasScale));
      canvasX = Math.floor(canvasX);
      canvasY = Math.floor(canvasY);
      if (maxX <= 0) maxX = 0;
      if (maxY <= 0) maxY = 0;
      if (canvasX < 0) { canvasX = 0; }
      if (canvasY < 0) { canvasY = 0; }
      if (canvasX > maxX) { canvasX = maxX; }
      if (canvasY > maxY) { canvasY = maxY; }
      hScrollBar.scrollPosition = canvasX;
      vScrollBar.scrollPosition = canvasY;
      hScrollBar.setScrollProperties(_container.width, 0, maxX);
      vScrollBar.setScrollProperties(_container.height, 0, maxY);
      _canvas.move(-canvasX * _canvasScale, -canvasY * _canvasScale);
    }
    
    private function hScrollHandler(evt:ScrollEvent):void {
      canvasX = hScrollBar.scrollPosition;
      moveCanvas();
    }

    private function vScrollHandler(evt:ScrollEvent):void {
      canvasY = vScrollBar.scrollPosition;
      moveCanvas();
    }
    public function scrollCanvas(x:Number, y:Number):void {
      canvasX = x; canvasY = y;
      moveCanvas();
    }
    /*
    public function scrollCanvas(dx:Number, dy:Number):void {
      canvasX += dx; canvasY += dy;
      moveCanvas();
    }
    */
    
    public function get canvasScrollPosition():Point {
      return new Point(canvasX, canvasY);
    }
    
    public function get canvasScale():Number {
      return _canvasScale;
    }
    
    public function get canvas():GPCanvas {
      return _canvas;
    }
        
    public function set pen(pen:GPPen):void {
      _canvas.pen = pen;
      pen.canvasWindow = this;
    }

    public function set statusText(value:String):void {
      this.status = value;
    }

    // NOTE: つかってない
    public function updateCanvas():void {
      var deg:Number = _canvas.rotation;
      var rad:Number = deg * Math.PI / 180;
      var scale:Number = _container.scaleX;
      
      // TODO: dasai
      if (deg >= 0) {
        if (deg <= 90) {
          _container.x = (Math.sin(rad) * _canvas.canvasHeight * scale);
          _container.y = 0;
        } else {
          _container.x = _canvas.canvasHeight * scale * Math.sin(rad) - Math.cos(rad) * _canvas.canvasWidth * scale;
          _container.y = - Math.cos(rad) * _canvas.canvasHeight * scale;
        }
      } else {
        if (deg >= -90) {
          _container.x = 0;
          _container.y = - Math.sin(rad) * _canvas.canvasWidth * scale;
        } else {
          _container.x = - Math.cos(rad) * _canvas.canvasWidth * scale;
          _container.y = - Math.sin(rad) * _canvas.canvasWidth * scale - Math.cos(rad) * _canvas.canvasHeight * scale;
        }
      }
    }
    
    public function zoomCanvas(m:Number):void {
      _canvasScale = m;
      _canvas.scaleX = _canvasScale;
      _canvas.scaleY = _canvasScale;
      moveCanvas();      
    }
    
    public function rotateCanvas(deg:int):void {
      this.rotation = deg;
      updateCanvas();
    }
 }
}