root/as3/gunyarapaint/trunk/gunyarapaint/src/gunyarapaint.as

import flash.events.Event;

import gunyarapaint.Canvas;
import gunyarapaint.Com;

import mx.controls.Alert;
import mx.events.ColorPickerEvent;
import mx.events.FlexEvent;
import mx.events.ListEvent;
import mx.events.NumericStepperEvent;
import mx.events.SliderEvent;

private var gpCanvas:gunyarapaint.Canvas;
private var basex:uint, basey:uint, baseWidth:uint, baseHeight:uint;

private var comm:Com;
private var oekakiId:uint;
private var redirectUrl:String;
private var onPost:Boolean = false;

private var canvasWidth:uint;
private var canvasHeight:uint;
private var undoBufferSize:uint;

private const ALERT_TITLE:String = 'お絵カキコ';
private const DEBUG:Boolean = false;

public function init():void {  
  // 通信系
  this.enabled = false;
  comm = new Com();
  comm.addEventListener('completeGetData', commCompleteHandler);
  
  if (parameters['postUrl'] && parameters['cookie'] && parameters['magic'] && parameters['redirectUrl']) {
    comm.setPostEnv(parameters['postUrl'], parameters['cookie'], parameters['magic']);
    postOekakiButton.enabled = true;
    redirectUrl = parameters['redirectUrl'];
  }
  if (parameters['undoBufferSize']) {
    undoBufferSize = int(parameters['undoBufferSize']);
    if (undoBufferSize < 0) {
      Alert.show('最大アンドゥ回数が少なすぎます。', ALERT_TITLE);      
    }
    if (undoBufferSize > 32) {
      Alert.show('最大アンドゥ回数が多すぎます。', ALERT_TITLE);      
    }
  } else {
    if (DEBUG) {
      undoBufferSize = 16;
    } else {
      return;
    }
  }
  if (parameters['oekakiId'] && parameters['baseImgUrl']) {
    oekakiId = uint(parameters['oekakiId']);
    var url:String = parameters['baseImgUrl'];
    comm.loadUrl(url);
    this.enabled = false;
  } else {
    if (parameters['canvasWidth'] && parameters['canvasHeight']) {
      canvasWidth = int(parameters['canvasWidth']);
      canvasHeight = int(parameters['canvasHeight']);
      if (canvasWidth < 16 || canvasHeight < 16) {
        Alert.show('キャンバスサイズが小さすぎます。', ALERT_TITLE);
        return;
      }
      if (canvasWidth > 600 || canvasHeight > 600) {
        Alert.show('キャンバスサイズが大きすぎます。', ALERT_TITLE);
        return;
      }
    } else {
      if (DEBUG) {
        canvasWidth = 300; canvasHeight = 400;
      } else {
        return;
      }
    }
    gpCanvas = new gunyarapaint.Canvas(canvasWidth, canvasHeight, undoBufferSize, null, null);
    initGunyaraPaintCanvas();
  }
  
  // 太さ
  thicknessStepper.addEventListener(NumericStepperEvent.CHANGE, thicknessStepperHandler);
  // カラーピッカ
  colorPicker.addEventListener(ColorPickerEvent.CHANGE, colorPickerHandler);
  // スポイト
  dropperButton.addEventListener(Event.CHANGE, dropperButtonHandler);
  // 透明度
  alphaSlider.addEventListener(SliderEvent.CHANGE, alphaSliderHandler);
  // キャンバス回転
  canvasRotate.addEventListener(SliderEvent.CHANGE, canvasRotateHandler);
  canvasRotate.addEventListener(SliderEvent.THUMB_DRAG, canvasRotateHandler);
  // 回転のときに勝手にApplicationの領域が拡大しないように
  canvas.explicitWidth = 0;
  canvas.explicitHeight = 0;
  
  // ブレンドモード
  blendModeComboBox.dataProvider = [
    {label: '通常', data: flash.display.BlendMode.NORMAL},
    // {label: '消去', data: flash.display.BlendMode.ERASE},
    {label: '比較(暗)', data: flash.display.BlendMode.DARKEN},
    {label: '乗算', data: flash.display.BlendMode.MULTIPLY},
    {label: '比較(明)', data: flash.display.BlendMode.LIGHTEN},
    {label: 'スクリーン', data: flash.display.BlendMode.SCREEN},
    {label: '覆い焼き', data: flash.display.BlendMode.ADD},
    {label: 'オーバーレイ', data: flash.display.BlendMode.OVERLAY},
    {label: 'ハードライト', data: flash.display.BlendMode.HARDLIGHT},
    {label: '差の絶対値', data: flash.display.BlendMode.DIFFERENCE},
    {label: '除外', data: flash.display.BlendMode.SUBTRACT},
    {label: '反転', data: flash.display.BlendMode.INVERT}];
  blendModeComboBox.addEventListener(ListEvent.CHANGE, blendModeComboBoxHandler);
  
  // アンドゥ・リドゥ
  undoButton.addEventListener(FlexEvent.BUTTON_DOWN, undoButtonHandler);
  redoButton.addEventListener(FlexEvent.BUTTON_DOWN, redoButtonHandler);
   
  // 補助線
  additionalNumberStepper.addEventListener(NumericStepperEvent.CHANGE, additionalNumberStepperHandler);
  additionalBoxCheckBox.addEventListener(Event.CHANGE, additionalBoxCheckBoxHandler);
  additionalSkewCheckBox.addEventListener(Event.CHANGE, additionalSkewCheckBoxHandler);
  
  postOekakiButton.addEventListener(FlexEvent.BUTTON_DOWN, postOekakiButtonHandler);
      
  this.enabled = true;
}

private function initGunyaraPaintCanvas():void {
  canvas.width = canvasWidth;
  canvas.height = canvasHeight;
  canvas.addChild(gpCanvas);
  // スポイトで色取ったイベント
  gpCanvas.addEventListener('changeColor', changeColorHandler);
  // undo/redoの状態変化
  gpCanvas.addEventListener('changeUndoRedo', changeUndoRedoHandler);
  gpCanvas.rotation = 0;

  this.width = canvasWidth + 20;
  this.height = canvasHeight + canvas.y + 10;
  
  canvas.x = 10;
  basex = canvas.x;
  basey = canvas.y;
  changeGunyaraPaintRect();

  // マウスボタンが上がったとき、canvasに教えてあげる
  this.addEventListener(MouseEvent.MOUSE_UP, gpCanvas.externalMouseUp);  

  toolCanvas.x = (this.width - toolCanvas.width) / 2;
}

private function commCompleteHandler(evt:Event):void {
  if (onPost) {
    onPost = false;
    if (comm.getErrorStr()) {
      // error
      Alert.show(comm.getErrorStr(), ALERT_TITLE);
      this.enabled = true;
    } else if (comm.getStringData() != '') {
      Alert.show(comm.getStringData(), ALERT_TITLE);
      this.enabled = true;
    } else {
      // redirect
      Com.redirect(redirectUrl);
    }
  } else {
    var baseImg:BitmapData = Bitmap(comm.getContent()).bitmapData;
    canvasWidth = baseImg.width;
    canvasHeight = baseImg.height;
    gpCanvas = new gunyarapaint.Canvas(0, 0, undoBufferSize, null, baseImg);
    initGunyaraPaintCanvas();
    this.enabled = true;
  }
}

private function thicknessStepperHandler(evt:NumericStepperEvent):void {
  gpCanvas.setLineThickness(evt.value);
}

private function colorPickerHandler(evt:ColorPickerEvent):void {
  gpCanvas.setLineColor(evt.target.selectedColor);
}

private function alphaSliderHandler(evt:SliderEvent):void {
  gpCanvas.setLineAlpha(evt.value);
}

private function canvasRotateHandler(evt:SliderEvent):void {
  gpCanvas.rotation = evt.value;
  
  var deg:int = gpCanvas.rotation;
  var rad:Number = deg * Math.PI / 180;
  // TODO: dasai
  if (deg >= 0) {
    if (deg <= 90) {
      canvas.x = Math.sin(rad) * canvasHeight + 10;
      canvas.y = basey;
      this.width = canvasHeight * Math.sin(rad) +
                    canvasWidth * Math.cos(rad) + 20;
      this.height = canvasHeight * Math.cos(rad) +
                     canvasWidth * Math.abs(Math.sin(rad)) + basey + 10;
    } else {
      canvas.x = canvasHeight * Math.sin(rad) - Math.cos(rad) * canvasWidth + 10;
      canvas.y = basey - Math.cos(rad) * canvasHeight;
      this.width = canvasHeight * Math.sin(rad) - Math.cos(rad) * canvasWidth + 20;
      this.height = -canvasHeight * Math.cos(rad) +
                     canvasWidth * Math.sin(rad) + basey + 10;
    }
  } else {
    if (deg >= -90) {
      canvas.x = basex;
      canvas.y = basey - Math.sin(rad) * canvasWidth;
      this.width = canvasHeight * Math.sin(Math.abs(rad)) +
                    canvasWidth * Math.cos(rad) + 20;
      this.height = canvasHeight * Math.cos(rad) +
                     canvasWidth * Math.abs(Math.sin(rad)) + basey + 10;
    } else {
      canvas.x = basex - Math.cos(rad) * canvasWidth;
      canvas.y = basey - Math.sin(rad) * canvasWidth - Math.cos(rad) * canvasHeight;
      this.width = basex - Math.cos(rad) * canvasWidth - Math.sin(rad) * canvasHeight + 20;
      this.height = basey - Math.sin(rad) * canvasWidth - Math.cos(rad) * canvasHeight + 10;
    }
  }
  changeGunyaraPaintRect();
}
private function changeGunyaraPaintRect():void {
  // 外部のスクリプト呼び出し。主に回転時のサイズ変更
  if (this.width < (toolCanvas.width + 4)) {
    this.width = toolCanvas.width + 4;
  }
  if (this.height < 312) { // for color picker
    this.height = 312;
  }
  if (ExternalInterface.available) {
    try {
      ExternalInterface.call("changeGunyaraPaintRect", this.width, this.height);
    } catch (e:SecurityError) {
    } catch (e:Error) {
    }
  }  
}

private function blendModeComboBoxHandler(evt:ListEvent):void {
  gpCanvas.setLineBlendMode(String(evt.currentTarget.value));
}
private function undoButtonHandler(evt:FlexEvent):void {
  gpCanvas.undo();
}
private function redoButtonHandler(evt:FlexEvent):void {
  gpCanvas.redo();
}
private function dropperButtonHandler(evt:Event):void {
  if (evt.target.selected) {
    gpCanvas.setPenMode(gpCanvas.MODE_DROPPER);    
  } else {
    gpCanvas.setPenMode(gpCanvas.MODE_PEN);
  }
}
private function changeColorHandler(evt:Event):void {
  colorPicker.selectedColor = gpCanvas.getLineColor();
  alphaSlider.value = 1.0;
}
private function additionalNumberStepperHandler(evt:NumericStepperEvent):void {
  gpCanvas.setAdditionalNumber(evt.value);
}
private function additionalBoxCheckBoxHandler(evt:Event):void {
  gpCanvas.setAdditionalBox(evt.target.selected);
}
private function additionalSkewCheckBoxHandler(evt:Event):void {
  gpCanvas.setAdditionalSkew(evt.target.selected);
}
private function changeUndoRedoHandler(evt:Event):void {
  var undoCount:Number = gpCanvas.getUndoCount();
  var redoCount:Number = gpCanvas.getRedoCount();
  if (undoCount > 0) {
    undoButton.label = 'アンドゥ (' + undoCount + ')';
    undoButton.enabled = true;
  } else {
    undoButton.label = 'アンドゥ';
    undoButton.enabled = false;
  }
  if (redoCount > 0) {
    redoButton.label = 'リドゥ (' + redoCount + ')';
    redoButton.enabled = true;
  } else {
    redoButton.label = 'リドゥ';
    redoButton.enabled = false;
  }
}

private function postOekakiButtonHandler(evt:Event):void {
  if (messageTextArea.text == '') {
    Alert.show('書き込みが空です。絵のタイトルなどの情報を書き込んでください。', ALERT_TITLE);
    return;
  }
  this.enabled = false;
  onPost = true;
  comm.postOekaki(fromTextInput.text,
                  messageTextArea.text,
                  gpCanvas.getPNGImage(),
                  gpCanvas.getCompressedLog(),
                  oekakiId);
}