root/as3/gunyarapaint/trunk/gunyarapaint/src/gplogplayer.mxml

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
  layout="absolute" width="420" height="349"
  backgroundGradientAlphas="[1.0, 1.0]"
  backgroundGradientColors="[#FFFFFF, #FFFFFF]"
  creationComplete="init()"
>
  <mx:Button id="playButton" x="10" y="9" label="再生" enabled="false"/>
  <mx:Label x="63" y="11" text="再生スピード"/>
  <mx:HSlider id="playSpeedHSlider" x="116" y="8" minimum="1" maximum="501" snapInterval="20" value="21" width="107"/>
  <mx:Button x="231" y="9" label="続きを描く" id="refButton"/>
  <mx:Canvas id="canvas" x="10" width="400" height="300" y="39" borderStyle="solid"></mx:Canvas>

  <mx:Script>
  <![CDATA[
  import mx.core.UIComponent;
  import flash.events.Event;
  import org.libspark.nicopedia.Com;
  import org.libspark.gunyarapaint.entities.GPLogger;
  import org.libspark.gunyarapaint.controls.GPCanvas;
  import org.libspark.gunyarapaint.utils.MiscUtils;

  import mx.controls.Alert;
  import mx.events.FlexEvent;
  import mx.events.SliderEvent;
  import mx.managers.PopUpManager;

  private var oelog:ByteArray;
  private var baseImg:BitmapData;
  private var baseImgInfo:Object;
  private var oekakiId:uint;
  private var postUrl:String;

  /*** debug ***/
  private var debugOekakiId:uint = 0; // 0でデバッグしない
  private var debugOekakiRefId:uint = 0;
  private var debugCheckPngUrl:String;
  private var debugCheckPng:ByteArray;
  /*** debug end ***/

  public function init():void {
    this.enabled = false;

    // for debug
    if (debugOekakiId != 0) {
      parameters['oelogUrl'] = 'http://dic.nicovideo.jp/oelog/' + debugOekakiId;
      if (debugOekakiRefId != 0) {
        parameters['baseImgUrl'] = 'http://dic.nicovideo.jp/oekaki_layers/' + debugOekakiRefId;
        parameters['baseImgInfoUrl'] = 'http://dic.nicovideo.jp/oekaki_info/' + debugOekakiRefId;
      }
      debugCheckPngUrl = 'http://dic.nicovideo.jp/oekaki/' + debugOekakiId + '.png';
      new Com().sendGetUrlRequest(debugCheckPngUrl, function(com:Com):void { debugCheckPng = com.data; });
    }

    if (parameters['oelogUrl']) {
      var url:String = parameters['oelogUrl'];
      new Com().sendGetUrlRequest(url, getOelogHandler);
    } else {
      return;
    }
    if (parameters['postUrl']) {
      postUrl = parameters['postUrl'];
    }
    if (parameters['oekakiId']) {
      oekakiId = uint(parameters['oekakiId']);
    }
    playButton.addEventListener(FlexEvent.BUTTON_DOWN, playButtonHandler);
    refButton.addEventListener(FlexEvent.BUTTON_DOWN, refButtonHandler);
    playSpeedHSlider.addEventListener(SliderEvent.CHANGE, playSpeedHSliderHandler);
    playSpeedHSlider.addEventListener(SliderEvent.THUMB_DRAG, playSpeedHSliderHandler);
  }

  private function getOelogHandler(com:Com):void {
    oelog = com.data;
    oelog.uncompress();
    if (parameters['baseImgUrl']) {
      new Com().loadURL(parameters['baseImgUrl'], getBaseImgHandler);
    } else {
      play();
    }
  }

  private function getBaseImgHandler(com:Com):void {
    baseImg = Bitmap(com.content).bitmapData;
    if (parameters['baseImgInfoUrl']) {
      new Com().sendGetUrlRequest(parameters['baseImgInfoUrl'], getBaseImgInfoHandler);
    } else {
      // 旧バージョン
      play();
    }
  }
  
  private function getBaseImgInfoHandler(com:Com):void {
    baseImgInfo = com.jsonObject;
    play();
  }

  private var _logger:GPLogger;

  private function playSpeedHSliderHandler(evt:SliderEvent):void {
    if (_logger) {
      _logger.playSpeed = playSpeedHSlider.value;
    }
  }

  private function playButtonHandler(evt:Event):void {
    play();
  }

  private function refButtonHandler(evt:Event):void {
    if (debugCheckPng) {
      checkImage();
    } else if (postUrl) {
      Com.redirectOekakiForm(postUrl, oekakiId);
    } else {
      Alert.show('続きが描けません！');
    }
  }

  private function play():void {
    playButton.enabled = false;

    if (baseImg && !baseImgInfo) {
      baseImgInfo = {'width': baseImg.width, 'height': baseImg.height, 'undoBufferSize': 16};
    }
    oelog.position = 0;
    _logger = GPLogger.createFromByteArray(oelog, false, baseImg, baseImgInfo);

    canvas.removeAllChildren();
    var tui:UIComponent = new UIComponent();
    tui.graphics.beginFill(0xFFFFFF);
    tui.graphics.drawRect(0, 0, _logger.canvasWidth, _logger.canvasHeight);
    tui.addChild(_logger.layerArray.view);
    canvas.addChild(tui);

    // canvas.rawChildren.addChild(_logger.layerArray.view);
    canvas.width = _logger.canvasWidth + 2;
    canvas.height = _logger.canvasHeight + 2;
    this.width = _logger.canvasWidth + 20;
    this.width = this.width < 420 ? 420 : this.width;
    this.height = _logger.canvasHeight + canvas.y + 20;
    this.height = this.height < 137 ? 137 : this.height; // for express install
    if (ExternalInterface.available) {
      try {
        ExternalInterface.call("changeGPLogPlayerRect", this.width, this.height);
      } catch (e:SecurityError) {
      } catch (e:Error) {
      }
    }
    this.enabled = true;

    _logger.play(playSpeedHSlider.value, completePlayLogHandler);
  }

  private function completePlayLogHandler():void {
    playButton.enabled = true;
  }

  private function checkImage():void {
    if (MiscUtils.compareObject(
        _logger.dataForPost['image'],
        debugCheckPng)) {
      Alert.show('合ってる。');
    } else {
      Alert.show('違うよ！');
    }
  }
  ]]>
  </mx:Script>
  <mx:Label x="313" y="11" text="ver.2008112301"/>
</mx:Application>