root/as3/Utils/src/org/libspark/utils/display/Sprite3DContainer.as

package org.libspark.utils.display
{
        import flash.display.DisplayObject;
        import flash.display.DisplayObjectContainer;
        import flash.display.Sprite;
        
        public class Sprite3DContainer extends Sprite
        {
                private var _children:Array = [];
                
                override public function addChild(child:DisplayObject):DisplayObject
                {
                        return addChildObject(super.addChild(child));
                }
                
                override public function addChildAt(child:DisplayObject, index:int):DisplayObject
                {
                        return addChildObject(super.addChildAt(child, index));
                }
                
                override public function removeChild(child:DisplayObject):DisplayObject
                {
                        return removeChildObject(super.removeChild(child));
                }
                
                override public function removeChildAt(index:int):DisplayObject
                {
                        return removeChildObject(super.removeChildAt(index));
                }
                
                private function addChildObject(child:DisplayObject):DisplayObject
                {
                        if (child != null) {
                                _children.push(new ChildObject(child));
                        }
                        return child;
                }
                
                private function removeChildObject(child:DisplayObject):DisplayObject
                {
                        var children:Array = _children;
                        var l:uint = children.length;
                        for (var i:int = 0; i < l; ++i) {
                                if ((children[i] as ChildObject).child == child) {
                                        children.splice(i, 1);
                                        --i;
                                        --l;
                                }
                        }
                        return child;
                }
                
                private function getRootParent():DisplayObjectContainer
                {
                        var d:DisplayObjectContainer = this;
                        while (d.parent != null) {
                                d = d.parent;
                        }
                        return d;
                }
                
                public function zSort():void
                {
                        var root:DisplayObjectContainer = getRootParent();
                        var children:Array = _children;
                        var l:uint = children.length;
                        var i:uint = 0;
                        for (i = 0; i < l; ++i) {
                                (children[i] as ChildObject).updateZ(root);
                        }
                        
                        children.sortOn('z', Array.NUMERIC | Array.DESCENDING);
                        
                        for (i = 0; i < l; ++i) {
                                setChildIndex((children[i] as ChildObject).child, i);
                        }
                }
        }
}

import flash.display.DisplayObject;
import flash.display.DisplayObjectContainer;
import flash.geom.Matrix3D;

internal class ChildObject
{
        public function ChildObject(child:DisplayObject)
        {
                this.child = child;
        }
        
        public var child:DisplayObject;
        public var z:Number;
        
        public function updateZ(parent:DisplayObjectContainer):void
        {
                var matrix:Matrix3D = child.transform.getRelativeMatrix3D(parent);
                if (matrix != null) {
                        z = matrix.position.z;
                }
        }
}