root/as3/ThreadViewer/ThreadViewer.as

/**
 * ThreadViewer for ActionScript Thread Library
 *
 * @author      Copyright (c) 2008 daoki2
 * @version     0.6
 * @link        http://www.libspark.org/wiki/daoki2/ThreadViewer
 * @link        http://homepage.mac.com/daoki2/
 *
 * Copyright (c) 2008 daoki2
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 */

import flash.events.*;
import flash.filesystem.*;
import flash.data.*;
import flash.desktop.NativeApplication;
import flash.net.LocalConnection;

import mx.events.*;
import mx.collections.ArrayCollection;
import mx.controls.*;

import org.libspark.snippets.AIRUtils.PreferenceUtil;
import org.libspark.thread.ThreadState;
import org.libspark.utils.SqlUtil;
import org.libspark.snippets.controls.ChartData.FusionCharts.SingleChartData;

private static const LEFT_PADD:uint = 38; // スレッド名のX座標
private var _conn:LocalConnection; // LocalConnection接続用
private var threadList:ArrayCollection = new ArrayCollection(); // スレッドリスト
private var threadNameLabel:ArrayCollection = new ArrayCollection(); // スレッド名Labelのリスト
private var threadStatus:ArrayCollection = new ArrayCollection(); // スレッド状態のリスト
private var threadLog:ArrayCollection = new ArrayCollection(); // スレッド遷移グラフのリスト
private var pos_x:Number = 0; // スレッド遷移グラフのX座標
private var isLogging:Boolean = false; // ログ収集中か否か
private var framePerSecond:uint = 24; // フレーム/秒
private var frameInterval:Number = 1000/24; // 時間(ms)/フレーム
private var _dbconn:SQLConnection; // ローカルデータベース接続用

/* ######## アプリケーション関連のハンドラ ######## */

/*
 * アプリケーションの初期化
 */
private function init():void {
    //　イベントハンドラの登録
    addEventListener(Event.CLOSING, onAppClosing);
    addEventListener(FlexNativeWindowBoundsEvent.WINDOW_RESIZE, onWinResize);
    threadName.addEventListener(MouseEvent.MOUSE_DOWN, threadName_MouseDownHandler);

    // プリファレンス(初期値)の読み込み
    var result:Object = PreferenceUtil.load(this, "preference.xml");
    if (!result.status)
        trace(result.message);

    // 注:最小サイズを設定した時の動作が謎すぎるので、とりあえずコメントアウト
    //this.minWidth = 780;
    //this.minHeight = 520;
    // ウィンドウサイズが最小サイズより小さければ是正
    //if (this.width < this.minWidth)
    //  this.width = this.minWidth + 16;
    //if (this.height < this.minHeight)
    //  this.height = this.minHeight + 16;

    this.visible = true;

    // LocalConnectionの作成
    _conn = new LocalConnection();
    _conn.client = this;

    try {
        // LocalConnectionに接続
        _conn.connect("AS3ThreadLibV1"); // 接続名
        _conn.allowDomain("*"); // どこからの接続でも許す

        // nopの生成
        createNop();

        // ローカルデータベースをオープン
        var dbFile:File = File.applicationDirectory.resolvePath("thread.db");
        _dbconn = new SQLConnection();
        _dbconn.open(dbFile, SQLMode.UPDATE);
        SqlUtil.executeSQLStatement(_dbconn, "delete from threadTime"); // 古いデータを削除
        SqlUtil.executeSQLStatement(_dbconn, "delete from threadState"); // 古いデータを削除

        // Chartの作業ファイルを設定
        threadStateHtml = File.applicationStorageDirectory.resolvePath("threadState.html");
        threadStateData = File.applicationStorageDirectory.resolvePath("threadState.xml");
        threadTimeHtml = File.applicationStorageDirectory.resolvePath("threadTime.html");
        threadTimeData = File.applicationStorageDirectory.resolvePath("threadTime.xml");
    } catch(argerr:ArgumentError) {
        trace("Can't connect...the connection name is already used by another SWF");
    } catch(error:Error) {
        trace(error.message);
    }
}

/*
 * アプリケーションの終了ハンドラ
 */
private function onAppClosing(event:Event):void {

    // プリファレンス(初期値)の書き込み
    var prefList:ArrayCollection = new ArrayCollection();
    prefList.addItem("nativeWindow.x"); // X座標
    prefList.addItem("nativeWindow.y"); // Y座標
    prefList.addItem("width"); // ウィンドウの幅
    prefList.addItem("height"); // ウィンドウの高さ
    PreferenceUtil.save(this, prefList, "preference.xml");

    // LocalConnectionをクローズ
    if (_dbconn != null)
        _dbconn.close();
}

/*
 * Windowのリサイズハンドラ
 */
private function onWinResize(event:FlexNativeWindowBoundsEvent):void {

    // スレッド名、スレッド遷移グラフの場所を元に戻す
    threadName.y = 0;
    threadTime.y = 0;

    // もしログ収集を止めてたら、スレッド実行時間のグラフを再描画
    if (!isLogging && threadList.length != 0)
        createThreadTimeChart();
}

/* ######## LocalConnection関連のイベントハンドラ ######## */

/*
 * 新規スレッドの取得ハンドラ
 */
public function threadEntryHandler(name:String, newThread:Boolean = true):void {
    
    // ログ収集中でなければ終わる
    if (!isLogging)
        return;
    
    // スレッドリスト中にあるか？
    if (threadList.contains(name)) {
        trace("Thread", name, "already exists"); // 既に同名のスレッドが存在する
    } else {
        // スレッド名のLabelを生成
        var t:Label = new Label();
        t.x = LEFT_PADD;
        t.y = threadList.length * 16;
        t.text = name;
        threadName.addChild(t);
        threadNameLabel.addItem(t);
        
        // スレッド状態のImageを生成
        var s:Image = new Image();
        s.x = 8;
        s.y = threadList.length * 16 + 1;
        if (newThread)
            s.source = "icons/NEW.png"; // 新規のスレッド
        else
            s.source = "icons/RUNNABLE.png"; //既存のスレッド
        
        threadName.addChild(s);
        threadStatus.addItem(s);
        
        // スレッドリストに登録
        threadList.addItem(name);
    }   
}

/*
 * スレッドの名称変更取得ハンドラ
 */
public function threadNameHandler(name:String, newName:String):void {

    // ログ収集中でなければ終わる
    if (!isLogging)
        return;

    // スレッドリスト中にあるか？
    if (!threadList.contains(name))
        threadEntryHandler(name, false); // 無いので、既存のスレッドとして登録

    // スレッドリストに登録されてるスレッド名を変更
    var index:int = threadList.getItemIndex(name);
    threadList.removeItemAt(index); // 古いスレッド名を削除
    threadList.addItemAt(newName, index); // 新しいスレッド名を登録

    // Labelリストから該当のLabelを取得して、スレッド名を更新する
    var n:Label = Label(threadNameLabel.getItemAt(index - 1)); // threadListは"nop"も含むので、ひとつ引く
    n.text = newName;
}

/*
 * スレッドの状態取得ハンドラ
 */
public function threadStateHandler(name:String, status:uint, time:int):void {

    // スレッド状態画像のファイル名　注:TERMINATINGとTERMINATEDは同じ画像を使う
    var StateImageFiles:Array = new Array("icons/NEW.png", "icons/RUNNABLE.png", "icons/WAITING.png",
                                          "icons/TIMED_WAITING.png", "icons/TERMINATED.png", "icons/TERMINATED.png");

    // ログ収集中でなければ終わる
    if (!isLogging)
        return;

    // スレッドリスト中にあるか？
    if (!threadList.contains(name))
        threadEntryHandler(name, false); // 無いので、既存のスレッドとして登録

    // 状態リストから該当のImageを取得して、画像を更新する
    var index:int = threadList.getItemIndex(name);
    var s:Image = Image(threadStatus.getItemAt(index - 1)); // threadListは"nop"も含むので、ひとつ引く
    s.source = StateImageFiles[status];

    // ローカルデータベースに情報を記録
    SqlUtil.executeSQLStatement(_dbconn, "insert into threadState(name, state, time) values ('" + name + "', " + status + ", " + time + ")");
}

private var b_color:uint = 0x0000ff; // スレッド遷移グラフのデフォルト色

/*
 * スレッドの実行時間取得ハンドラ
 */
public function threadTimeHandler(name:String, startTime:int, endTime:int):void {

    // ログ収集中でなければ終わる
    if (!isLogging)
        return;

    // スレッドリスト中にあるか？
    if (!threadList.contains(name))
        threadEntryHandler(name, false); // 無いので、既存のスレッドとして登録

    var pos_y:int = threadList.getItemIndex(name) * 16; // スレッド遷移グラフのY座標
 
    // スレッド遷移グラフの生成
    var b:VBox = new VBox();
    b.x = pos_x;
    b.y = pos_y;
    b.toolTip = String(endTime - startTime) + "ms";
    b.width = (endTime - startTime) * hsScale.value;
    b.height = 16;
    b.setStyle("backgroundColor", b_color);
    threadTime.addChild(b);
    threadLog.addItem({bar:b, time:(endTime - startTime)}); // スレッド遷移グラフリストへ登録

    pos_x += b.width; // 次回の描画X座標の計算

    // もしフレーム同期ハンドラが呼ばれた直後だったら？
    // 注:フレーム同期の直後は"nop"が来る
    if (name == "nop") {
        checkInterval(endTime, endTime - startTime); // フレーム同期間隔の確認

        // フレーム毎に色を入れ替える
        if (b_color == 0x0000ff)
                b_color = 0x8888ff;
        else
                b_color = 0x0000ff;
    }

    // ローカルデータベースに情報を記録
    SqlUtil.executeSQLStatement(_dbconn, "insert into threadTime(name, startTime, endTime, elapse) values ('" + name + "', " + startTime + ", " + endTime + ", " + (endTime - startTime) + ")");
    tElapseTime.text = convertElapseTime(pos_x);
}

/* ######## コンポーネントのイベントハンドラ ######## */

/*
 * Record/Stopボタンのクリックハンドラ
 */
private function bRecordStop_ClickHandler(event:MouseEvent):void {

    hsScale.enabled = isLogging; // 縮尺スケーラを有効/無効にする

    // もしログ収集中だったら？
    if (isLogging) {
        // ログ収集を止める
        bRecordStop.toolTip = "Record"; // ログ収集を止めるから次回は"Record"。ややこしい... 
        threadList.removeItemAt(0); // スレッドリストから"nop"を削除
        // もしスレッドが１つでもあれば
        if (threadList.length != 0) {
            // スレッド選択コンボボックスの更新
            cbThread.dataProvider = threadList;
            cbThread.selectedItem = threadList.getItemAt(0);

            // スレッド状態Chartの作成
            createThreadStateChart(String(threadList.getItemAt(0)));

            // スレッド実行時間のアップデート
            updateThreadTimes(String(threadList.getItemAt(0)));

            // スレッド実行時間Chartの作成
            createThreadTimeChart();
        }
    } else {
        bRecordStop.toolTip = "Stop"; // ログ収集を始めるから次回は"Stop"。やっぱりややこしい...
    }

    isLogging = !isLogging; // ログ収集中なら止める。収集してなかったら、始める。
    bRecordStop.enabled = isLogging; // Recordボタンを無効/有効にする
}

/*
 * Clearボタンのクリックハンドラ
 */
private function bClear_ClickHandler(event:MouseEvent):void {

    // 管理リストの削除
    threadLog.removeAll();
    threadList.removeAll();
    threadNameLabel.removeAll();
    threadStatus.removeAll();

    // スレッド遷移グラフの削除
    threadName.removeAllChildren();
    threadTime.removeAllChildren();    
    pos_x = 0; // 描画X座標を先頭に戻す

    // 画面に表示されてるコンポーネント関連を初期化
    bRecordStop.enabled = true;
    cbThread.dataProvider = null;
    tIssue.text = "";
    tElapse.text = "";
    tAveTime.text = "";
    tMaxTime.text = "";
    tMinTime.text = "";
    htmlState.htmlText = "";
    htmlTime.htmlText = "";
    tElapseTime.text = "00:00:00.000";
    tElapseMax.text = "Max 00.000";
    tElapseMin.text = "Min 00.000";
    tElapseAve.text = "Ave 00.000";
    tFPS.text = "FPS: 000";
    threadName.y = 0;
    threadTime.y = 0;

    // 内部変数の初期化
    frameGet = false;
    maxInterval = 0;
    maxIntPos = 0;
    minInterval = 10000;
    minIntPos = 0;
    lastNopTime = 0;
    totalInterval = 0;
    intervalCount = 0;

    // ローカルデータベースの古いデータを削除
    SqlUtil.executeSQLStatement(_dbconn, "delete from threadTime");
    SqlUtil.executeSQLStatement(_dbconn, "delete from threadState");

    // nopを生成
    createNop();
}

/*
 * スケールの変更ハンドラ
 */
private function hsScale_ChangeHandler(event:SliderEvent):void {

    // 描画X座標を先頭に戻す
    pos_x = 0;

    // スレッド遷移グラフの位置とサイズを更新
    for each (var val:* in threadLog) {
        var b:VBox = VBox(val.bar);
        var time:int = int(val.time);
        b.x = pos_x;
        b.width = time * event.value; // 縮尺と時間からサイズを計算
        pos_x += b.width;
    }
}

/*
 * スレッド選択コンボボックスのクローズハンドラ
 */
private function cbThread_CloseHandler(event:Event):void {
    
    // スレッド状態Chartの作成
    createThreadStateChart(String(ComboBox(event.target).selectedItem));

    // スレッド実行時間の更新
    updateThreadTimes(String(ComboBox(event.target).selectedItem));
}

/*
 * インフォメーション表示
 */
private function bInfo_ClickHandler(event:MouseEvent):void {
    // Publisher IDをアラートで表示
    Alert.show(NativeApplication.nativeApplication.publisherID, 'Publisher ID');
}

/*
 * Interval Maxラベルのクリックハンドラ
 */
private function tElapseMax_ClickHandler(event:MouseEvent):void {
    // フレーム同期間隔が最大の場所にスクロール
    threadTimeContainer.horizontalScrollPosition = maxIntPos * hsScale.value;
}

/*
 * Interval Minラベルのクリックハンドラ
 */
private function tElapseMin_ClickHandler(event:MouseEvent):void {
    // フレーム同期間隔が最小の場所にスクロール
    threadTimeContainer.horizontalScrollPosition = minIntPos * hsScale.value;
}

/*
 * threadNameのドラッグ制御
 */
private var m_x:Number;
private var m_y:Number;
private function threadName_MouseDownHandler(event:MouseEvent):void {

    // 現座標の登録
    m_x = event.stageX;
    m_y = event.stageY;

    // イベントハンドラの登録
    threadName.addEventListener(MouseEvent.MOUSE_MOVE, threadName_MouseMoveHandler);
    threadName.addEventListener(MouseEvent.MOUSE_UP, threadName_MouseUpHandler);
}

private var chata:Array = new Array(1, -1); // チャタリング防止用のバッファ
private var chata_cancel:int = 0; // チャタリング防止キャンセルのカウンタ
private function threadName_MouseMoveHandler(event:MouseEvent):void {

    // もしスレッド名が表示領域に収まらないなら
    if (threadName.height > threadName.parent.height) {
        var delta_y:Number = event.stageY - m_y; // 移動量の計算
        var pos_y:Number = threadName.y + delta_y; // Y座標を求める

        // チャタリング防止のアルゴリズム:
        // 過去2回のドラッグ方向(上もしくは下)と違ったらチャタリングと判断してキャンセル
        // ただし、同じ方向に2回続けば、チャタリングじゃないと判断
        if (chata[0] < 0 && chata[1] < 0) {
            if (delta_y >= 0 && chata_cancel < 2) {
                pos_y = 1;
                chata_cancel++;
            } else {
                chata[0] = chata[1];
                chata[1] = delta_y;
                chata_cancel = 0;
            }
        } else if (chata[0] >=0 && chata[1] >= 0) {
            if (delta_y < 0 && chata_cancel < 2) {
                pos_y = 1;
                chata_cancel++;
            } else {
                chata[0] = chata[1];
                chata[1] = delta_y;
                chata_cancel = 0;
            }
        } else {
            chata[0] = chata[1];
            chata[1] = delta_y;
        }

        // 移動可能か？
        if ((pos_y <= 0) && (pos_y > (threadName.parent.height - threadName.height))) {
            threadName.y = pos_y;
            threadTime.y = pos_y;
        }
    }

    // 現座標を更新
    m_x = event.stageX;
    m_y = event.stageY;
}

private function threadName_MouseUpHandler(event:MouseEvent):void {

    // イベントハンドラを削除
    threadName.removeEventListener(MouseEvent.MOUSE_MOVE, threadName_MouseMoveHandler);
    threadName.removeEventListener(MouseEvent.MOUSE_UP, threadName_MouseUpHandler);

    // チャタリング防止解除
    chata[0] = 1;
    chata[1] = -1;
    chata_cancel = 0;
}

/* ######## ローカル関数 ####### */

/*
 * スレッドの状態の割合グラフの生成
 */
private var threadStateHtml:File = null; // 作業ファイル
private var threadStateData:File = null; // 作業ファイル
private function createThreadStateChart(name:String):void {

    // それぞれのスレッド状態の時間を求める
    var result:ArrayCollection = getThreadStateTime(name);

    // スレッドの状態が1つ以上あればChartを生成
    if (result.length != 0) {
        var chartData:SingleChartData = new SingleChartData();
        chartData.graphAttribute.decimalPrecision = "0";
        chartData.graphAttribute.formatNumberScale = "0";
        for each (var val:* in result) {
            chartData.addSetElement(val);
        }
        chartData.createHtmlFile(threadStateHtml, "Doughnut2D", htmlState.width, htmlState.height, threadStateData.nativePath);
        chartData.createDataFile(threadStateData);
        htmlState.location = "file:///" + threadStateHtml.nativePath;
    } else
        htmlState.htmlText = ""; // 空のHTMLを表示
}

/*
 * スレッドの状態時間の演算
 */
private function getThreadStateTime(name:String):ArrayCollection {

    // Chart用の情報
    var stateName:Array = new Array("NEW", "RUNNABLE", "WAITING", "TIMED_WAITING", "TERMINATING", "TEMINATED"); // スレッドの状態名
    var stateColor:Array = new Array("E1E1E1", "00FF00", "FF0000", "FFFF00", "656565", "656565"); // スレッドの状態色
    var elapse:Array = new Array(0, 0, 0, 0, 0, 0); // スレッドの状態時間

    // 該当スレッドの状態データを取得
    var result:Array = SqlUtil.getData(_dbconn, "select name, state, time from threadState where name == '" + name + "'");

    var currentState:int = 0;
    var lastTime:int = 0;
    var value:ArrayCollection = new ArrayCollection();

    // もし状態データが存在すれば
    if (result[1].data != null) {
        for each (var val:* in result[1].data) {
            elapse[currentState] += (val.time - lastTime); // スレッドの状態時間を計算する
            currentState = val.state;
            lastTime = val.time;
        }
        // スレッドの状態遷移が1つ以上あれば
        if (result[1].data.length > 1) {
            // スレッドの状態時間をChart用データに登録
            for (var i:uint = 1; i < 6; i++)
                value.addItem({name: stateName[i], value: elapse[i], color: stateColor[i]});
        } else {
            // 無ければスレッドの状態時間は正しく求められないので、仕方ないからスレッドの実行時間を状態時間として求める
            var result2:Array = SqlUtil.getData(_dbconn, "select sum(elapse) as value from threadTime where name =='" + name + "'");
            if (result2[1].data != null) {
                value.addItem({name: stateName[0], value: 0, color: stateColor[0]}); // ダミーデータ
                value.addItem({name: stateName[currentState], value: result2[1].data[0].value, color: stateColor[currentState]});
            }
        }
    }
    return value;
}

/*
 * スレッドの実行時間等の情報更新
 */
private function updateThreadTimes(name:String):void {
    // 該当スレッドの実行回数を取得
    var result:Array = SqlUtil.getData(_dbconn, "select count(*) as issue from threadTime where name == '" + name + "'");

    // もしデータがあれば
    if (result[1].data != null) {
        // スレッドの実行回数
        tIssue.text = result[1].data[0].issue;

        // スレッドの総実行時間を取得
        result = SqlUtil.getData(_dbconn, "select sum(elapse) as value from threadTime where name == '" + name + "'");
        tElapse.text = result[1].data[0].value;

        // スレッドの平均実行時間を計算
        tAveTime.text = "" + int(tElapse.text) / int(tIssue.text);

        // スレッドの最長実行時間を取得
        result = SqlUtil.getData(_dbconn, "select max(elapse) as value from threadTime where name == '" + name + "'");
        tMaxTime.text = result[1].data[0].value;

        // スレッドの最短実行時間を取得
        result = SqlUtil.getData(_dbconn, "select min(elapse) as value from threadTime where name == '" + name + "'");
        tMinTime.text = result[1].data[0].value;
    } else {
        // データ無い...
        tIssue.text = "";
        tElapse.text = "";
        tAveTime.text = "";
        tMaxTime.text = "";
        tMinTime.text = "";
    }
}

/*
 * スレッドの実行時間のグラフ生成
 */
private var threadTimeHtml:File = null;
private var threadTimeData:File = null;
private function createThreadTimeChart():void {

    // スレッドの実行時間データを求める
    var result:ArrayCollection = getThreadElapseTime();

    // スレッドの実行時間Chartの生成
    var chartData:SingleChartData = new SingleChartData();
    chartData.graphAttribute.decimalPrecision = "0";
    chartData.graphAttribute.formatNumberScale = "0";
    for each (var val:* in result) {
        chartData.addSetElement(val);
    }
    chartData.createHtmlFile(threadTimeHtml, "Bar2D", htmlTime.width, htmlTime.height, threadTimeData.nativePath);
    chartData.createDataFile(threadTimeData);
    htmlTime.location = "file:///" + threadTimeHtml.nativePath;
}

/*
 * スレッドの実行時間の計算
 */
private function getThreadElapseTime():ArrayCollection {

    // それぞれのスレッドの実行時間の合計を得る
    var result:Array = SqlUtil.getData(_dbconn, "select name, sum(elapse) as value from threadTime group by name order by value desc");

    var value:ArrayCollection = new ArrayCollection(); // Chart用データ
    var cnt:int = 0;
    var etc_time:int = 0; // TOP 10以外のスレッドの実行時間の合計

    for each (var val:* in result[1].data) {
        // まだTOP 10が求まってなければ
        if (cnt < 10) {
            value.addItem({name: val.name, value: val.value}); // 実行時間をChartデータに登録
        } else {
            // TOP 10以外のスレッドの実行時間を足す
            etc_time += val.value;
        }
        cnt++;
    }

    // スレッドが10個以上あれば
    if (cnt >= 10)
        value.addItem({name: "etc.", value: etc_time}); // TOP 10以外のスレッドの実行時間をChartデータに登録

    return value;
}

/*
 * フレーム同期間隔の確認/更新
 */
private var frameGet:Boolean = false; // フレーム同期を既に受け取ったか
private var lastNopTime:int = 0; // 最後にnopが来た時間
private var maxInterval:int = 0; // フレーム間隔の最大値
private var maxIntPos:int = 0; // 最大フレーム間隔が発生した時間
private var minInterval:int = 10000; // フレーム間隔の最小値 デフォルト値:10秒
private var minIntPos:int = 0; // 最小フレーム間隔が発生した時間
private var totalInterval:int = 0; // 総フレーム間隔時間
private var intervalCount:int = 0; // フレーム同期回数
private function checkInterval(t:int, period:int):void {
    var intervalTime:int = 0;
    
    // もしフレーム同期を既に取得済みなら
    if (frameGet) {
        intervalTime = t - lastNopTime; // 同期間隔を求める
    } else {
        intervalTime = period;
        frameGet = true;
    }
    totalInterval += intervalTime;
    intervalCount++;

    // もし現在の最大値より大きかったら
    if (intervalTime > maxInterval) {
        maxInterval = intervalTime;
        maxIntPos = pos_x - intervalTime;
        tElapseMax.text = "Max " + convertElapseTime(maxInterval).substring(6);
    }

    // もし現在の最小値よりも小さかったら
    if (intervalTime < minInterval) {
        minInterval = intervalTime;
        minIntPos = pos_x - intervalTime;
        tElapseMin.text = "Min " + convertElapseTime(minInterval).substring(6);
    }

    var ave_time:int = totalInterval/intervalCount; // 平均フレーム間隔時間を求める
    tElapseAve.text = "Ave " + convertElapseTime(ave_time).substring(6);
    tFPS.text = "FPS: " + int(1000 / ave_time); // FPSを計算
    lastNopTime = t; // 現在時間の更新
}

/*
 * 時間(ms)を文字列 "HH:MM:SS.SSS" に変換
 */
private function convertElapseTime(time:int):String {
    var elapseTime:Date = new Date(time);
    var value:String = "";
    if (elapseTime.hoursUTC < 10)
        value += "0";
    value += (elapseTime.hoursUTC + ":");
    if (elapseTime.minutesUTC < 10)
        value += "0";
    value += (elapseTime.minutesUTC + ":");
    if (elapseTime.secondsUTC < 10)
        value += "0";
    value += (elapseTime.secondsUTC + ".");
    if (elapseTime.millisecondsUTC < 100)
        value += "0";
    if (elapseTime.millisecondsUTC < 10)
        value += "0";
    value += (elapseTime.millisecondsUTC + "");
    return value;    
}

/*
 * nopを生成
 */
private function createNop():void {
    threadList.addItem("nop"); // スレッドリストに"nop"を登録
    var t:Label = new Label();
    t.x = LEFT_PADD; t.y = 0; t.text = "nop";
    threadName.addChild(t);
}

/*
 * Frame Per Second(FPS)情報の取得ハンドラ
 */
public function frameInfoHandler(fps:uint):void {
    framePerSecond = fps;
    frameInterval = 1000/framePerSecond;
}