root/as3/Thread/branches/soumen/src/org/libspark/thread/threads/display/DraggerThread.as

/*
 * ActionScript Thread Library
 * 
 * Licensed under the MIT License
 * 
 * Copyright (c) 2008 BeInteractive! (www.be-interactive.org) and
 *                    Spark project  (www.libspark.org)
 * 
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 * 
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 * 
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 * 
 */
package org.libspark.thread.threads.display
{
        import flash.display.Sprite;
        import flash.events.MouseEvent;
        import flash.geom.Point;
        import org.libspark.thread.Thread;
        
        /**
        * Spriteをドラッグ&ドロップさせるためのスレッドです。
        * 
        * <p>このスレッドを start すると、対象の Sprite に対して MOUSE_DOWN, MOUSE_UPイベントを設定し、
        * それぞれのハンドラで startDrag, stopDrag を呼び出します。</p>
        *
        * <p>イベント発生時の MouseEvent は、それぞれ DownEvent, UpEvent で取得できます。</p>
        * 
        * @author uwi
        */
        public class DraggerThread extends Thread 
        {
                private var _target : Sprite;
                private var _downevent : MouseEvent = null;
                private var _upevent : MouseEvent = null;
                
                public function DraggerThread(target : Sprite) {
                        _target = target;
                }
                
                override protected function run() : void
                {
                        onMouseUp(null);
                }
                
                protected function onMouseUp(e : MouseEvent) : void
                {
                        _upevent = e;
                        _target.stopDrag();
                        event(_target, MouseEvent.MOUSE_DOWN, onMouseDown);
                }
                
                protected function onMouseDown(e : MouseEvent) : void
                {
                        _upevent = null;
                        _downevent = e;
                        _target.startDrag();
                        event(_target, MouseEvent.MOUSE_UP, onMouseUp);
                }
                
                public function delta() : Point
                {
                        if (_downevent != null && _upevent != null) {
                                return new Point(_upevent.stageX - _downevent.stageX, _upevent.stageY - _downevent.stageY);
                        }
                        return null;
                }
                
                public function get Target() : Sprite { return _target; }
                public function get DownEvent() : MouseEvent { return _downevent; }
                public function get UpEvent() : MouseEvent { return _upevent; }
        }
        
}