root/as3/Syndication/trunk/src/org/libspark/syndication/RSSFeedEntry.as

/**
 * ActionScript Syndication Library
 *
 * Copyright (c) 2008 Takanobu Izukawa (humming.via-kitchen.com) and
 *                    Spark project    (www.libspark.org)
 *
 * Dual licensed under the MIT (MIT-LICENSE.txt)
 * and GPL (GPL-LICENSE.txt) licenses.
 *
 */
package org.libspark.syndication
{
    import org.libspark.syndication.namespaces.rss;
    import org.libspark.syndication.namespaces.rdf;
    import org.libspark.syndication.namespaces.dc;
    import org.libspark.syndication.namespaces.content;
    import org.libspark.syndication.utils.DateUtil;

    use namespace rss;
    use namespace rdf;
    use namespace dc;
    use namespace content;

    /**
     *  IFeedEntry インターフェイスの実装クラスで RSS 1.0 に対応した実装を提供します。
     */
    public class RSSFeedEntry implements IFeedEntry
    {
        /**
         *  エントリーのデータを保持します。
         */
        private var _data:XML;

        /**
         *  @inheritDoc
         */
        public function get author():String
        {
            return _data.dc::creator.toString();
        }

        /**
         *  @inheritDoc
         */
        public function get title():String
        {
            return _data.title.toString();
        }

        /**
         *  @inheritDoc
         */
        public function get link():String
        {
            return _data.link.toString();
        }

        /**
         *  @inheritDoc
         */
        public function get description():String
        {
            return _data.content::encoded.toString();
        }

        /**
         *  公開日の情報を保持します。
         */
        private var _published:Date;

        /**
         *  @inheritDoc
         */
        public function get published():Date
        {
            if (_published == null && !!_data.dc::date.toString())
            {
                _published = DateUtil.parseW3C(_data.dc::date.toString());
            }
            return _published;
        }
        
        /**
         *  カテゴリーの情報を保持します。
         */
        private var _categories:Array;
        
        /**
         *  @inheritDoc
         */
        public function get categories():Array
        {
            if (_categories == null)
            {
                _categories = [];
                for each (var nodeData:XML in _data.dc::subject)
                {
                    _categories.push(nodeData.toString());
                }
            }
            return _categories;
        }

        /**
         *  新しい RSSFeedEntry クラスのインスタンスを作成します。
         *
         *  @param data             RSS 1.0 エントリーの XML
         */
        public function RSSFeedEntry(data:XML)
        {
            _data = data;
        }

        /**
         *  @inheritDoc
         */
        public function toString():String
        {
            return title;
        }
    }
}