root/as3/Syndication/trunk/src/org/libspark/syndication/RSSFeed.as

/**
 * ActionScript Syndication Library
 *
 * Copyright (c) 2008 Takanobu Izukawa (humming.via-kitchen.com) and
 *                    Spark project    (www.libspark.org)
 *
 * Dual licensed under the MIT (MIT-LICENSE.txt)
 * and GPL (GPL-LICENSE.txt) licenses.
 *
 */
package org.libspark.syndication
{
    import org.libspark.syndication.namespaces.rss;
    import org.libspark.syndication.namespaces.rdf;
    import org.libspark.syndication.namespaces.dc;
    import org.libspark.syndication.namespaces.content;

    use namespace rss;
    use namespace rdf;
    use namespace dc;
    use namespace content;

    /**
     *  IFeed インターフェイスの実装クラスで RSS 1.0 に対応した実装を提供します。
     */
    public class RSSFeed implements IFeed
    {
        /**
         *  フィードのデータを保持します。
         */
        private var _data:XML;
        
        /**
         *  @inheritDoc
         */
        public function get title():String
        {
            return _data.channel.title.toString();
        }

        /**
         *  @inheritDoc
         */
        public function get link():String
        {
            return _data.channel.link.toString();
        }

        /**
         *  エントリーの情報を保持します。
         */
        private var _entries:Array;
        
        /**
         *  @inheritDoc
         */
        public function get entries():Array
        {
            if (_entries == null)
            {
                _entries = [];
                for each (var nodeData:XML in _data.item)
                {
                    _entries.push(new RSSFeedEntry(nodeData));
                }
            }
            return _entries;
        }

        /**
         *  新しい RSSFeed クラスのインスタンスを作成します。
         */
        public function RSSFeed(data:XML)
        {
            _data = data;
        }
        
        /**
         *  @inheritDoc
         */
        public function toString():String
        {
            return title;
        }
    }
}