root/as3/Syndication/trunk/src/org/libspark/syndication/RSS2Feed.as

/**
 * ActionScript Syndication Library
 *
 * Copyright (c) 2008 Takanobu Izukawa (humming.via-kitchen.com) and
 *                    Spark project    (www.libspark.org)
 *
 * Dual licensed under the MIT (MIT-LICENSE.txt)
 * and GPL (GPL-LICENSE.txt) licenses.
 *
 */
package org.libspark.syndication
{
    import org.libspark.syndication.namespaces.dc;
    import org.libspark.syndication.namespaces.content;

    use namespace dc;
    use namespace content;
    
    /**
     *  IFeed インターフェイスの実装クラスで RSS 2.0 に対応した実装を提供します。
     */
    public class RSS2Feed implements IFeed
    {
        /**
         *  フィードのデータを保持します。
         */
        private var _data:XML;

        /**
         *  @inheritDoc
         */
        public function get title():String
        {
            return _data.channel.title.toString();
        }

        /**
         *  @inheritDoc
         */
        public function get link():String
        {
            return _data.channel.link.toString();
        }
        
        /**
         *  エントリーの情報を保持します。
         */
        private var _entries:Array;
        
        /**
         *  @inheritDoc
         */
        public function get entries():Array
        {
            if (_entries == null)
            {
                _entries = [];
                for each (var nodeData:XML in _data.channel.item)
                {
                    _entries.push(new RSS2FeedEntry(nodeData));
                }
            }
            return _entries;
        }

        /**
         *  新しい RSS2Feed クラスのインスタンスを作成します。
         *
         *  @param data         rss 2.0 フィードの XML
         */
        public function RSS2Feed(data:XML)
        {
            _data = data;
        }
        
        /**
         *  @inheritDoc
         */
        public function toString():String
        {
            return title;
        }
    }
}