root/as3/Syndication/trunk/src/org/libspark/syndication/Feed.as

/**
 * ActionScript Syndication Library
 *
 * Copyright (c) 2008 Takanobu Izukawa (humming.via-kitchen.com) and
 *                    Spark project    (www.libspark.org)
 *
 * Dual licensed under the MIT (MIT-LICENSE.txt)
 * and GPL (GPL-LICENSE.txt) licenses.
 *
 */
package org.libspark.syndication
{
    import flash.errors.IllegalOperationError;
    import flash.utils.getQualifiedClassName;
    import org.libspark.syndication.errors.UnknownFeedError;
    import org.libspark.syndication.namespaces.rss;
    import org.libspark.syndication.namespaces.atom;
    import org.libspark.syndication.namespaces.atom03;

    /**
     *  Feed.
     */
    public class Feed implements IFeed
    {
        /**
         *  a reference of feed adapter object.
         */
        private var _data:IFeed;
        
        /**
         *  @inheritDoc
         */
        public function get title():String
        {
            return _data.title;
        }
        
        /**
         *  @inheritDoc
         */
        public function get link():String
        {
            return _data.link;
        }

        /**
         *  @inheritDoc
         */
        public function get entries():Array
        {
            return _data.entries;
        }
        
        /**
         *  Constructor.
         */
        public function Feed(data:IFeed)
        {
            _data = data;
        }
        
        /**
         *  @inheritDoc
         */
        public function toString():String
        {
            return '[Feed data="'+getQualifiedClassName(_data)+'"]';
        }
        
        /**
         *  フィードをパースする
         *
         *  @param data             Feedの文字列かXML
         *  @return                 Feedオブジェクト
         *  @throws
         *      IllegalOperationError
         *      UnknownFeedError
         */
        public static function parse(data:*):Feed
        {
            //  文字列ならばXMLへキャスト
            if (data is String)
            {
                data = XML(data);
            }

            //  dataがXMLで無ければExceptionを投げる
            if (data is XML === false)
            {
                throw new IllegalOperationError('first argument must be String or XML.');
            }

            var localName:String = data.localName();
            var version:String = data.@version.toString();
            var nsList:Array = data.namespaceDeclarations();
            nsList = nsList.map(function (...a):String { return a[0].uri; });
            
            var adapter:IFeed;
            if (localName == 'rss' && !!version)
            {
                adapter = new RSS2Feed(data);
            }
            else if (nsList.indexOf(rss.uri) !== -1)
            {
                adapter = new RSSFeed(data);
            }
            else if (nsList.indexOf(atom.uri) !== -1)
            {
                adapter = new AtomFeed(data);
            }
            else if (nsList.indexOf(atom03.uri) !== -1)
            {
                adapter = new Atom03Feed(data);
            }
            else
            {
                            throw new UnknownFeedError("Unable to determine feed type.");
            }
            return new Feed(adapter);
        }
    }
}