root/as3/Syndication/trunk/src/org/libspark/syndication/AtomFeedEntry.as

/**
 * ActionScript Syndication Library
 *
 * Copyright (c) 2008 Takanobu Izukawa (humming.via-kitchen.com) and
 *                    Spark project    (www.libspark.org)
 *
 * Dual licensed under the MIT (MIT-LICENSE.txt)
 * and GPL (GPL-LICENSE.txt) licenses.
 *
 */
package org.libspark.syndication
{
    import org.libspark.syndication.namespaces.atom;
    import org.libspark.syndication.utils.DateUtil;

    use namespace atom;

    /**
     *  IFeedEntry インターフェイスの実装クラスで Atom に対応した実装を提供します。
     */
    public class AtomFeedEntry implements IFeedEntry
    {
        /**
         *  エントリーのデータを保持します。
         */
        private var _data:XML;

        /**
         *  @inheritDoc
         */
        public function get author():String
        {
            return _data.author.name.toString();
        }

        /**
         *  @inheritDoc
         */
        public function get title():String
        {
            return _data.title.toString();
        }

        /**
         *  @inheritDoc
         */
        public function get link():String
        {
            return _data.link.(@type.match(/^text\/html$/)).@href.toString();
        }

        /**
         *  @inheritDoc
         */
        public function get description():String
        {
            return _data.content.toString();
        }

        /**
         *  公開日の情報を保持します。
         */
        private var _published:Date;

        /**
         *  @inheritDoc
         */
        public function get published():Date
        {
            if (_published == null && !!_data.published.toString())
            {
                _published = DateUtil.parseW3C(_data.published.toString());
            }
            return _published;
        }
        
        /**
         *  カテゴリーの情報を保持します。
         */
        private var _categories:Array;
        
        /**
         *  @inheritDoc
         */
        public function get categories():Array
        {
            if (_categories == null)
            {
                _categories = [];
                for each (var nodeData:XML in _data.category)
                {
                    _categories.push(nodeData.@term.toString());
                }
            }
            return _categories;
        }
        
        /**
         *  新しい AtomFeedEntry クラスのインスタンスを作成します。
         *
         *  @param data             Atom エントリーの XML
         */
        public function AtomFeedEntry(data:XML)
        {
            _data = data;
        }

        /**
         *  @inheritDoc
         */
        public function toString():String
        {
            return title;
        }
    }
}