root/as3/Syndication/trunk/src/org/libspark/syndication/AtomFeed.as

/**
 * ActionScript Syndication Library
 *
 * Copyright (c) 2008 Takanobu Izukawa (humming.via-kitchen.com) and
 *                    Spark project    (www.libspark.org)
 *
 * Dual licensed under the MIT (MIT-LICENSE.txt)
 * and GPL (GPL-LICENSE.txt) licenses.
 *
 */
package org.libspark.syndication
{
    import org.libspark.syndication.namespaces.atom;
    
    use namespace atom;
    
    /**
     *  IFeed インターフェイスの実装クラスで Atom に対応した実装を提供します。
     */
    public class AtomFeed implements IFeed
    {
        /**
         *  フィードのデータを保持します。
         */
        private var _data:XML;

        /**
         *  @inheritDoc
         */
        public function get title():String
        {
            return _data.title.toString();
        }
        
        /**
         *  @inheritDoc
         */
        public function get link():String
        {
            return _data.link.(@type.match(/^text\/html$/)).@href.toString();
        }

        /**
         *  エントリーの情報を保持します。
         */
        private var _entries:Array;
        
        /**
         *  @inheritDoc
         */
        public function get entries():Array
        {
            if (_entries == null)
            {
                _entries = [];
                for each (var nodeData:XML in _data.entry)
                {
                    _entries.push(new AtomFeedEntry(nodeData));
                }
            }
            return _entries;
        }
        
        /**
         *  新しい AtomFeed クラスのインスタンスを作成します。
         *
         *  @param data             atom フィードの XML
         */
        public function AtomFeed(data:XML)
        {
            _data = data;
        }
        
        /**
         *  @inheritDoc
         */
        public function toString():String
        {
            return title;
        }
    }
}