root/as3/Study/BookmarkletBuilder/BookmarkletBuilder.mxml

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="420" height="450" applicationComplete="init()" xmlns:containers="flexlib.containers.*" xmlns:bmb="bmb.*">

        <mx:Script>
                <![CDATA[
                        import bmb.EditorPanel;
                        import flash.net.*;
                        
                        private static const TIMER_DURATION:Number = 4000;
                        
                        private var panelCnt:int = 0;
                        private var so:SharedObject;
                        
                        private var needSave:Boolean = false;
                        private var timer:Timer
                        
                        public function init():void
                        {
                                //restore tab and codes if there is SharedObject
                                so = SharedObject.getLocal("BookmarkletBuilder");
                                
                                var codes:Array = so.data.codes;
                                var tabIndex:int = so.data.tabIndex;
                                var ep:EditorPanel
                                
                                if(codes==null || codes.length == 0){
                                        ep = createPanel();
                                }else{
                                        for(var i:int=0; i<codes.length; i++){
                                                ep = createPanel();
                                                ep.text = codes[i];
                                                tabNavigator.selectedIndex = tabIndex;
                                        }
                                }
                                
                                //timer for autosave
                                timer = new Timer(TIMER_DURATION, 0);
                                timer.addEventListener(TimerEvent.TIMER, timerEventHandler);
                                timer.start();
                                
                                needSave = false;
                        }
                        
                        
                        public function createPanel():EditorPanel
                        {
                                panelCnt++;
                                var ep:EditorPanel = new EditorPanel();
                                ep.label = "script" + panelCnt;
                                ep.addEventListener(Event.CHANGE, editorPanelChanged,false,0,true);
                                tabNavigator.addChild(ep);
                                
                                return ep;
                        }
                        
                        
                        // copy javascript to the clipboard
                        public function copyJS():void
                        {
                                var str:String = EditorPanel(tabNavigator.selectedChild).text;
                                
                                var js:String = formatJS(str);
                                System.setClipboard(js);
                        }
                        
                        
                        // run javascript written in the textarea
                        public function executeJS():void
                        {
                                var str:String = EditorPanel(tabNavigator.selectedChild).text;
                                var req:URLRequest = new URLRequest( formatJS(str, true) );
                                navigateToURL(req, "_self");
                        }
                        
                        
                        //create bookmarklet javascript from script
                        public function formatJS(str:String, debugMode:Boolean=false):String
                        {
                                var js:String = "javascript:(function(){";
                                if(debugMode)
                                        js += "try{";
                                
                                js += str.split("\r").join("");
                                
                                if(debugMode)
                                        js += "}catch(error){alert(error)}";
                                
                                js += "})()";
                                
                                return js;
                        }
                        
                        
                        public function newTab():void
                        {
                                var ep:EditorPanel = EditorPanel(createPanel());
                                tabNavigator.selectedChild = ep;
                        }
                        
                        
                        /*
                        --------------------------------------------------------------
                        Autosave Implementation
                        --------------------------------------------------------------
                        */
                        
                        private function editorPanelChanged(e:Event):void
                        {
                                flagSave();
                        }
                        
                        private function flagSave():void
                        {
                                needSave = true;
                                if(timer){
                                        timer.reset();
                                        timer.start();
                                }
                        }
                        
                        
                        private function timerEventHandler(e:Event):void
                        {
                                if(needSave)
                                        saveCode();
                        }
                        
                        private function saveCode():void
                        {
                                var obj:Object = {};
                                obj.tabIndex = tabNavigator.selectedIndex;
                                
                                var ar:Array = [];
                                var imax:int = tabNavigator.numChildren;
                                for(var i:int=0; i<imax; i++){
                                        ar.push( EditorPanel(tabNavigator.getChildAt(i)).text );
                                }
                                so.data.codes = ar;
                                so.flush();
                                        
                                needSave = false;
                        }
                ]]>
        </mx:Script>
        <containers:SuperTabNavigator id="tabNavigator" change="flagSave()" childRemove="flagSave()" width="400" height="400">
        </containers:SuperTabNavigator>
        <mx:Button id="execute_btn" click="executeJS()" x="354" y="418" label="Run" />
        <mx:Button x="10" y="418" click="copyJS()" label="Copy as Bookmarklet" toolTip="Copy formatted code as a bookmarklet"/>
        <mx:Button id="new_btn0" click="newTab()" x="298" y="418" label="New" />
</mx:Application>