root/as3/SirdsAS3/org/libspark/dsler/SirdsAS3/RDSImageCreator.as

/**
 * - SirdsAS3 -
 * RDS/SISステレオグラム生成ライブラリ
 * 
 * RDSImageCreatorクラス
 * グレースケール画像(深度マップ画像)からRDSイメージを生成
 * 
 * @author              dsler
 * @version             1.0.0
 * @update      2009/07/02
 *
 * Licensed under The MIT License
 * Copyright (c) 2009 dsler
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 */

package org.libspark.dsler.SirdsAS3
{       
        import flash.display.Bitmap;
        import flash.display.BitmapData;
        import flash.display.Sprite;
        import flash.geom.Point;
        import flash.geom.Rectangle;
        
        public class RDSImageCreator implements IRDSImageCreatable
        {
                protected var _pattern:BitmapData;
                protected var _canvasDefinition:Rectangle;
                protected var _density:Number;
                protected var _originalPatternWidth:int;
                protected var _depthRange:int;
                
                public function RDSImageCreator(canvasWidth:int, canvasHeight:int, rdsPatternWidth:int = 100, depthRange:int = 20, density:Number = 1){
                        _canvasDefinition = new Rectangle(0, 0, canvasWidth, canvasHeight);
                        _originalPatternWidth = rdsPatternWidth; _depthRange = depthRange; _density = density;
                }
                
                public function create(dep:BitmapData):RDSImage{
                        var rdsImage:Sprite = new Sprite, depthMap:BitmapData = dep.clone();
                        var canvasHeight:int = _canvasDefinition.height, canvasWidth:int = _canvasDefinition.width;
                        var rdsSurface:BitmapData = new BitmapData(canvasWidth, canvasHeight);
                        
                        var t:Number = (new Date).getTime();
                         for(var i:int = 0; i < canvasHeight; i++){
                                var iterator:int = 0, oldDepth:uint = 0;
                                //新規オリジナルランダムドットパターンを設定
                                _pattern = createNewRandomPattern(_originalPatternWidth);
                                for(var j:int = 0; j < canvasWidth; j++){
                                        var newDepth:int = ( ( depthMap.getPixel(j, i) / 0xffffff ) * _depthRange + 0.5 ) >> 0, depthSub:int = newDepth - oldDepth;
                                        if(depthSub != 0){
                                                //上昇、下降処理(ランダムパターンの更新)
                                                if(depthSub > 0) _pattern = createDeletedPattern(_pattern, iterator % _pattern.width, depthSub);
                                                else if(depthSub < 0) _pattern = createInsertedPattern(_pattern, iterator % _pattern.width, - depthSub);
                                                iterator = 0;
                                        }
                                        rdsSurface.setPixel(j, i, _pattern.getPixel(iterator++ % _pattern.width, 0));
                                        oldDepth = newDepth;
                                }
                        } 
                        trace("convert time: ", ((new Date).getTime()-t)*0.001+"sec");
                        rdsImage.addChild(new Bitmap(rdsSurface));
                        return(new RDSImage(rdsImage, _originalPatternWidth, depthMap));
                }
                
                //新しいランダムドットパターンを生成
                protected function createNewRandomPattern(width:int):BitmapData{
                        var randomPattern:BitmapData = new BitmapData(width, 1);
                        for(var xi:int = 0; xi < width; xi++){
                                var random:Number = Math.random()*256, seed:uint = random >> 0;
                                if(( random - seed ) < _density) randomPattern.setPixel(xi, 0, seed << 16 | seed << 8 | seed);
                        }
                        return(randomPattern);
                }
                
                //ある区間を削除したパターンを生成(上昇処理)
                protected function createDeletedPattern(prevPattern:BitmapData, delPoint:uint, delWidth:uint):BitmapData{
                        var returnPattern:BitmapData = new BitmapData(prevPattern.width - delWidth, 1), bWidth:int = 0, prevPatternWidth:int = prevPattern.width;
                        if(prevPatternWidth - delPoint - delWidth > 0){
                                //通常の場合
                                returnPattern.copyPixels(prevPattern, new Rectangle(delPoint + delWidth, 0, prevPatternWidth - delPoint - delWidth, 1), new Point(0, 0));
                                bWidth = prevPatternWidth - delPoint - delWidth;
                        }else{
                                //削除範囲がパターン幅外に及ぶ場合
                                returnPattern.copyPixels(prevPattern, new Rectangle(delPoint + delWidth - prevPatternWidth, 0, prevPatternWidth - delWidth, 1), new Point(0, 0));
                        }
                        if(bWidth && delPoint > 0) returnPattern.copyPixels(prevPattern, new Rectangle(0, 0, delPoint, 1), new Point(bWidth, 0));
                        return(returnPattern);
                }
                
                //ある幅のランダムドットを追加したパターンを生成(下降処理)
                protected function createInsertedPattern(prevPattern:BitmapData, edgeAt:int, insertRandWidth:int):BitmapData{
                        var prevPatternWidth:int = prevPattern.width, returnPattern:BitmapData = new BitmapData(prevPatternWidth + insertRandWidth, 1);
                        returnPattern.copyPixels(prevPattern, new Rectangle(edgeAt, 0, 1, 1), new Point(0, 0));
                        returnPattern.copyPixels(createNewRandomPattern(insertRandWidth), new Rectangle(0, 0, insertRandWidth, 1), new Point(1, 0));
                        if(prevPatternWidth - edgeAt - 1 > 0) returnPattern.copyPixels(prevPattern, new Rectangle(edgeAt + 1, 0, prevPatternWidth - edgeAt - 1, 1), new Point(insertRandWidth + 1, 0));
                        if(edgeAt > 0) returnPattern.copyPixels(prevPattern, new Rectangle(0, 0, edgeAt, 1), new Point(prevPatternWidth - edgeAt + insertRandWidth, 0));
                        return(returnPattern);
                }
        }
}