root/as3/SirdsAS3/org/libspark/dsler/SirdsAS3/RDSColorImageCreator.as

/**
 * - SirdsAS3 -
 * RDS/SISステレオグラム生成ライブラリ
 * 
 * RDSColorImageCreatorクラス
 * SIRDSのカラーイメージを生成
 * 
 * @author              dsler
 * @version             1.0.0
 * @update      2009/07/02
 *
 * Licensed under The MIT License
 * Copyright (c) 2009 dsler
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 */

/**
 * convertHSV, convertRGBは下記の著作者、及びライセンスのもと公開されたコードです
 * 
 * Copyright 2007 Michiyasu Wada
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 * 
 * コード改変:AS3対応、パフォーマンスチューン
 */

package org.libspark.dsler.SirdsAS3
{
        import __AS3__.vec.Vector;
        import flash.display.BitmapData;
        
        public class RDSColorImageCreator extends RDSImageCreator
        {
                private var _hsv:Vector.<Number>;
                
                public function RDSColorImageCreator(canvasWidth:int, canvasHeight:int, rdsPatternWidth:int=100, depthRange:int=20, density:Number=1, color:uint = 0xff0000)
                {
                        super(canvasWidth, canvasHeight, rdsPatternWidth, depthRange, density);
                        _hsv = convertHSV(color >> 16, (color & 0x00ff00) >> 8, color & 0x0000ff);
                }
                
                //新しいランダムドットパターンを生成(カラー)
                override protected function createNewRandomPattern(width:int):BitmapData{
                        var randomPattern:BitmapData = new BitmapData(width, 1);
                        for(var xi:int = 0; xi < width; xi++){
                                var random:Number = Math.random()*100, seed:uint = random >> 0, rgb:Vector.<Number> = convertRGB(_hsv[0], seed, 100);
                                if( (random - seed) < _density ) randomPattern.setPixel(xi, 0, rgb[0] << 16 | rgb[1] << 8 | rgb[2]);
                        }
                        return(randomPattern);
                }

                public function convertHSV( r:Number, g:Number, b:Number ):Vector.<Number>
                {
                        var hsv:Vector.<Number> = new Vector.<Number>, h:Number = 0, s:Number = 0, v:Number = 0, x:Number, y:Number;;
                        r/=255; g/=255; b/=255;
                        if(r>=g) x=r; else x=g; if(b>x) x=b;
                        if(r<=g) y=r; else y=g; if(b<y) y=b;
                        v=x; 
                        var c:Number = x - y;
                        if(x==0) s=0; else s=c/x;
                        if(s!=0){
                                if(r==x){
                                        h=(g-b)/c;
                                } else {
                                        if(g==x){
                                                h=2+(b-r)/c;
                                        } else {
                                                if(b==x){
                                                        h=4+(r-g)/c;
                                                }
                                        }
                                }
                                h=h*60;
                                if(h<0) h+=360;
                        }
                        hsv.push(h, s*100, v*100);
                        return(hsv);
                }
                
                public function convertRGB( h:Number, s:Number, v:Number ):Vector.<Number>
                {
                        s=s*0.01, v=v*0.01;
                        var rgb:Vector.<Number> = new Vector.<Number>, r:Number=0, g:Number=0, b:Number=0, i:Number, x:Number, y:Number, z:Number;
                        if(s<0) s=0; if(s>1) s=1; if(v<0) v=0; if(v>1) v=1;
                        h=h%360; if(h<0) h+=360; h/=60;
                        i = h >> 0;
                        x=v*(1-s); y=v*(1-s*(h-i)); z=v*(1-s*(1-h+i));
                        switch(i){
                                case 0 : r=v; g=z; b=x; break;
                                case 1 : r=y; g=v; b=x; break;
                                case 2 : r=x; g=v; b=z; break;
                                case 3 : r=x; g=y; b=v; break;
                                case 4 : r=z; g=x; b=v; break;
                                case 5 : r=v; g=x; b=y; break;
                        }
                        rgb.push(r*255, g*255, b*255);
                        return(rgb);
                }
                
        }
}