root/as3/SQLControls/src/org/libspark/snippets/controls/SQLTableGrid.as

/**
 * The SQL TableGrid Class for AIR Application
 *
 * @author      Copyright (c) 2008 daoki2
 * @version     1.0.1
 * @link        http://snippets.libspark.org/
 * @link        http://homepage.mac.com/daoki2/
 *
 * Copyright (c) 2008 daoki2
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 */

package org.libspark.snippets.controls {
    import flash.data.SQLConnection;
    import mx.collections.ArrayCollection;
    import mx.controls.Alert;
    import mx.controls.DataGrid;
    import mx.controls.dataGridClasses.*;
    import org.libspark.utils.SqlUtil;
    import org.libspark.snippets.controls.SQLControlsClasses.checkBoxRenderer;
    import mx.core.ClassFactory;

    public class SQLTableGrid extends DataGrid {
        public var sqlConnection:SQLConnection = null;
        private static const typeData:Array = new Array("INTEGER", "FLOAT", "TEXT", "BLOB");

       /**
        * Constructor
        */
        public function SQLTableGrid(mode:Boolean = false) {
            super();
            var dataColumns:Array = new Array();
            dataColumns.push(new DataGridColumn("name"));

            var typeColumn:DataGridColumn = new DataGridColumn("type");
            var typeEditor:ClassFactory = new ClassFactory(mx.controls.ComboBox);
            typeEditor.properties = {dataProvider: typeData};
            typeColumn.itemEditor = typeEditor;
            dataColumns.push(typeColumn);

            var pkColumn:DataGridColumn = new DataGridColumn("primaryKey");
            var pkRenderer:ClassFactory = new ClassFactory(checkBoxRenderer);
            pkColumn.editorDataField = "checkBoxSelected";
            pkRenderer.properties = {dataField: "primaryKey", checkBoxEnabled: mode};
            pkColumn.itemRenderer = pkRenderer;
            pkColumn.rendererIsEditor = true;
            dataColumns.push(pkColumn);

            var aiColumn:DataGridColumn = new DataGridColumn("autoIncrement");
            var aiRenderer:ClassFactory = new ClassFactory(checkBoxRenderer);
            aiRenderer.properties = {dataField: "autoIncrement", checkBoxEnabled: mode};
            aiColumn.itemRenderer = aiRenderer;
            aiColumn.editorDataField = "checkBoxSelected";
            aiColumn.rendererIsEditor = true;
            dataColumns.push(aiColumn);

            var anColumn:DataGridColumn = new DataGridColumn("allowNull");
            var anRenderer:ClassFactory = new ClassFactory(checkBoxRenderer);
            anRenderer.properties = {dataField: "allowNull", checkBoxEnabled: mode};
            anColumn.itemRenderer = anRenderer;
            anColumn.editorDataField = "checkBoxSelected";
            anColumn.rendererIsEditor = true;
            dataColumns.push(anColumn);

            this.columns = dataColumns;
        }

       /**
        * Get the column information from the specified table and apply to DataGrid
        * @param        table   The table to get the column information
        */
        public function getColumnInfo(table:String):void {
            if (sqlConnection == null) {
                Alert.show("sqlConnection is null", "ERROR!");
                return;
            }
            if (!sqlConnection.connected) {
                Alert.show("SQLConnection is not connected", "ERROR!");
                return;
            }
            var columnDef:ArrayCollection = SqlUtil.getColumnDef(sqlConnection, table);
            this.dataProvider = columnDef;
        }
    }
}