root/as3/SQLControls/samples/SQLiteViewer/SQLiteViewer.as

import flash.events.*;
import mx.events.*;
import mx.collections.ArrayCollection;
import flash.filesystem.*;
import flash.net.FileFilter;
import flash.data.*;
import org.libspark.utils.SqlUtil;
import org.libspark.snippets.controls.SQLDataGrid;
import org.libspark.snippets.controls.SQLTableGrid;
import mx.containers.TitleWindow;

private var connection:SQLConnection = null;

private function bDBOpen_click(event:MouseEvent):void {
    var dbFile:File = null;
    if (tDBFilename.text == "") {
        dbFile = new File();
        var dbFilter:FileFilter = new FileFilter("DB File", "*.db");
        try {
            dbFile.browseForOpen("Open", [dbFilter]);
            dbFile.addEventListener(Event.SELECT, dbFileSelected);
        } catch (error:Error) {
            trace("Failed:", error.message);
        }
    } else {
        dbFile = new File("file://" + tDBFilename.text);
        GetTableList(dbFile);
    }
}

private function dbFileSelected(event:Event):void {
    tDBFilename.text = event.target.nativePath;
    GetTableList(File(event.target));
}

[Bindable]
private var lTableList_data:ArrayCollection = new ArrayCollection();

private function GetTableList(file:File):void {
    if (connection != null) {
        if (connection.connected) {
            try {
                connection.close();
            } catch (error:Error) {
                trace("Failed:", error.message);
            }
        }
    }

    connection = new SQLConnection();
    try {
        connection.open(file, SQLMode.READ);
        var _tableList:Array = SqlUtil.getTableList(connection);
        for each(var val:* in _tableList)
            lTableList_data.addItem(val);
        dbTable.sqlConnection = connection;
        dbQuery.sqlConnection = connection;
    } catch (error:Error) {
        trace("Failed:", error.message);
    }
}

private function lTableList_change(event:ListEvent):void {
    dbTable.getColumnInfo(String(List(event.target).selectedItem));
}

private function bSQLExec_click(event:MouseEvent):void {
    dbQuery.executeQuery(tSQLStatement.text);
}

private var dbQuery:SQLDataGrid = null;
private var dbTable:SQLTableGrid = null;

private function init():void {
    dbTable = new SQLTableGrid();
    dbTable.x = 290; dbTable.y = 60; dbTable.width = 490; dbTable.height = 205;
    addChild(dbTable);
    dbQuery = new SQLDataGrid();
    dbQuery.x = 20; dbQuery.y = 320; dbQuery.width = 760; dbQuery.height = 260;
    addChild(dbQuery);
}