root/as3/ListURLLoader/net/boondockradio/load/ListURLLoader.as

/**
 * ListURLLoader
 *
 * Licensed under the MIT License
 *
 * Copyright (c) 2009 BOONDOCK RADIO (boondockradio.net)
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 * 
 * 
 * 複数のデータを一度に読み込むクラスです。
 * 
 * [ sample code ]
 * 
 * var listURLLoader:ListURLLoader = new ListURLLoader();
 * listURLLoader.list = [ "aaa.xml", "bbb.xml", "ccc.xml" ];
 * listURLLoader.addEventListener(Event.INIT, function():void {
 *              listURLLoader.removeEventListener(Event.INIT, arguments.callee);
 *              trace(listURLLoader.data);
 * });
 * listURLLoader.start();
 */

package net.boondockradio.load
{
        import flash.errors.IOError;
        import flash.events.Event;
        import flash.events.EventDispatcher;
        import flash.events.IOErrorEvent;
        import flash.net.URLLoader;
        import flash.net.URLRequest;

        public class ListURLLoader extends EventDispatcher
        {
                
                
                /**
                 * write only member
                 */
                private var _list:Array;
                public function set list (value:Array):void
                {
                        _list = value;
                }
                
                /**
                 * read only member
                 */
                private var _data:Array;
                public function get data ():Array { return _data; }
                
                
                // use for URLLoader List
                private var _loadList:Array = new Array();
                
                // complete count
                private var _cnt:int = 0;
                
                
                /**
                 * constructor
                 */
                public function ListURLLoader() {}
                
                /**
                 * load start
                 */
                public function start():void
                {
                        if(_list == null) {
                                throw new ArgumentError("読み込み対象がありません。 / doesn't have load target.");
                                return;
                        }
                        
                        _init();
                }
                
                
                
                /**
                 * initialize
                 */
                private function _init():void
                {
                        for(var i:int = 0; i < _list.length; i++) {
                                _loadList[i] = new URLLoader();
                                _loadList[i].addEventListener(Event.COMPLETE, _onComplete);
                                _loadList[i].addEventListener(IOErrorEvent.IO_ERROR, _onError);
                                _loadList[i].load(new URLRequest(_list[i]));
                        }
                }
                
                /**
                 * load complete
                 */
                private function _onComplete(e:Event):void
                {
                        e.target.removeEventListener(e.type, arguments.callee);
                        
                        _cnt++;
                        
                        if(_loadList.length == _cnt) {
                                _data = new Array();
                                for(var i:int = 0; i < _loadList.length; i++) {
                                        _data[i] = _loadList[i].data;
                                }
                                dispatchEvent(new Event(Event.INIT));
                        }
                }
                
                /**
                 * IO Error
                 */
                private function _onError(e:IOErrorEvent):void
                {
                        e.target.removeEventListener(e.type, arguments.callee);
                        dispatchEvent(e);
                }
                
        }
}