root/as3/ChartData/src/org/libspark/snippets/controls/ChartData/FusionCharts/SingleChartData.as

/**
 * SingleChartData - The HTML & XML Build class for FusionCharts
 *
 * @author      Copyright (c) 2008 daoki2
 * @version     0.5.0
 * @link        http://homepage.mac.com/daoki2/
 *
 * Copyright (c) 2008 daoki2
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 */

package org.libspark.snippets.controls.ChartData.FusionCharts {
    import flash.utils.ByteArray;
    import flash.filesystem.*;

    public class SingleChartData {
        public var graphAttribute:Object = {
            bgColor: "",
            bgAlpha: "",
            bgSWF: "",
            canvasBgColor: "",
            canvasBgAlpha: "",
            canvasBorderColor: "",
            canvasBorderThickness: "",
            caption: "",
            subCaption: "",
            xAxisName: "",
            yAxisName: "",
            yAxisMinValue: "",
            yAxisMaxValue: "",
            showNames: "",
            showValues: "",
            showLimits: "",
            rotateNames: "",
            animation: "",
            showColumnShadow: "",
            baseFont: "",
            baseFontSize: "",
            baseFontColor: "",
            outCnvBaseFont: "",
            outCnvBaseFontSize: "",
            outCnvBaseFontColor: "",
            numberPrefix: "",
            numberSuffix: "",
            formatNumber: "",
            formatNumberScale: "",
            decimalSeparator: "",
            thousandSeparator: "",
            decimalPrecision: "",
            divLineDecimalPrecision: "",
            limitsDecimalPrecision: "",
            zeroPlaneThickness: "",
            zeroPlaneColor: "",
            zeroPlaneAlpha: "",
            numdivlines: "",
            divlinecolor: "",
            divLineThickness: "",
            divLineAlpha: "",
            showDivLineValue: "",
            showAlternateHGridColor: "",
            alternateHGridColor: "",
            alternateHGridAlpha: "",
            numVDivLines: "",
            VDivlinecolor: "",
            VDivLineThickness: "",
            VDivLineAlpha: "",
            alternateVGridColor: "",
            alternateVGridAlpha: "",
            showhovercap: "",
            hoverCapBgColor: "",
            hoverCapBorderColor: "",
            hoverCapSepChar: "",
            charLeftMargin: "",
            charRightMargin: "",
            charTopMargin: "",
            charBottomMargin: ""
        };

        private var setElements:Array = new Array();
        private var lineElements:Array = new Array();
        private var defaultColor:Array = [
            "AFD8F8", "F6BD0F", "8BBA00", "FF8E46", "008E8E", "D64646", "8E468E", "588526", "B3AA00", "008ED6", "9D080D", "A186BE"
        ];

        /**
         * Constructor 
         */
        public function SingleChartData():void {
        }

        /**
         * Create HTML File
         * @param  file         HTML file to create
         * @param  chartType    Chart type (Column2D, Column3D, Pie2D, Pie3D, Line, Bar2D, Area2D, Doughnut2D)
         * @param  width        Chart width
         * @param  height       Chart height
         * @param  dataFilename Data file name string
         * @return object       If the operation succeed. Contains the following property.
         *                      - status : true/false
         *                      - message: message text
         */
        public function createHtmlFile(file:File, chartType:String, width:uint, height:uint, dataFilename:String):Object {
            var appDir:String = File.applicationDirectory.nativePath.split("\\").join("/");
            var html:String = "<!DOCTYPE html PUBLIC \"-//W3C//DTD XHTML 1.0 Transitional//EN\" \"http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd\">\n";
            html += "<html xmlns=\"http://www.w3.org/1999/xhtml\">\n";
            html += "  <head>\n";
            html += "    <meta http-equiv=\"Content-Type\" content=\"text/html; charset=UTF-8\" />\n";
            html += "    <script language=\"javascript\" src=\"file://" + appDir + "/JSClass/FusionCharts.js\"></script>\n";
            html += "  </head>\n";
            html += "  <body>\n";
            html += "    <div id=\"FusionCharts\"/>\n";
            html += "    <script language=\"javascript\" type=\"text/javascript\">\n";
            html += "      var chart = new FusionCharts(\"file://" + appDir + "/Charts/FCF_" + chartType + ".swf\", \"ChartId\", \"" + width + "\", \"" + height + "\");\n";
            html += "      chart.setDataURL(\"file://" + dataFilename.split("\\").join("/") + "\");\n";
            html += "      chart.render(\"FusionCharts\");\n";
            html += "    </script>\n";
            html += "  </body>\n";
            html += "</html>";
            try {
                var fs:FileStream = new FileStream();
                fs.open(file, FileMode.WRITE);
                fs.writeUTFBytes(html);
                fs.close();
            } catch (err:Error) {
                return {status: false, message: err.message};
            }
            return {status: true, message: ""};
        }

        /**
         * Create Data File
         * @param  file         Data file to create
         * @return object       If the operation succeed. Contains the following property.
         *                      - status : true/false
         *                      - message: message text
         */
        public function createDataFile(file:File):Object {
            var BOM:ByteArray = new ByteArray(); // Byte Order Mark of UTF-8
            BOM.writeByte(0xEF);
            BOM.writeByte(0xBB);
            BOM.writeByte(0xBF);
            try {
                var fs:FileStream = new FileStream();
                fs.open(file, FileMode.WRITE);
                fs.writeBytes(BOM);
                fs.writeUTFBytes(toXML());
                fs.close();
            } catch (err:Error) {
                return {status: false, message: err.message};
            }
            return {status: true, message: ""};
        }

        private function toXML():String {
            var xml:String = "<graph";
            for (var val:* in this.graphAttribute) {
                if (this.graphAttribute[val] != "")
                    xml += " " + val + "=\"" + this.graphAttribute[val] + "\"";
            }
            xml += ">\n";
            xml += toSetElement();
            xml += toTrendLinesElement();
            xml += "</graph>";
            return xml;
        }

        private function toSetElement():String {
            var result:String = "";
            var index:uint = 0;
            if (this.setElements.length > 0) {
                for each (var val:* in this.setElements) {
                    result += "<set";
                    for (var attr:* in val) {
                        if (val[attr] != "") {
                            result += " " + attr + "=\"" + val[attr] + "\"";
                        } else {
                            if (attr == "color") {
                                result += " " + attr + "=\"" + defaultColor[index++] + "\"";
                                if (index >= defaultColor.length)
                                    index = 0;
                            }
                        }
                    }
                    result += "/>\n";
                }
            }
            return result;
        }

        private function toTrendLinesElement():String {
            var result:String = "";
            if (this.lineElements.length > 0) {
                result += "<trendLines>\n";
                for each (var val:* in this.lineElements) {
                    result += "<line";
                    for (var attr:* in val) {
                        if (val[attr] != "")
                            result += " " + attr + "=\"" + val[attr] + "\"";
                    }
                    result += ">\n";
                }
                result += "</trendLines>\n";
            }
            return result;
        }

        public function addSetElement(obj:Object):void {
            this.setElements.push(obj);
        }

        public function addLineElement(obj:Object):void {
            this.lineElements.push(obj);
        }

        public function getSetElement():Object {
            var result:Object = new Object();
            result = {name: "", value: "", color: "", hoverText: "", link: "", alpha: "", showName: ""};
            return result;
        }

        public function getLineElement():Object {
            var result:Object = new Object;
            result = {startValue: "", endValue: "", color: "", displayValue: "", thickness: "", isTrendZone: "", showOnTop: "", alpha: ""};
            return result;
        }

        public function clear():void {
            for (var val:* in this.graphAttribute)
                this.graphAttribute[val] = "";
                this.setElements = new Array();
                this.lineElements = new Array();
        }
    }
}