root/as3/Astro/Torus3D_01/src/primitives/Torus.as

package primitives
{
    import flash.geom.Vector3D;
    
    public class Torus
    {
        public var vertices:Vector.<Vector3D>;
        public var indices:Vector.<int>;
        public var uvtData:Vector.<Number>;
        
        private var _innerRadius:Number;
        private var _outerRadius:Number;
        private var _sides:int;
        private var _rings:int;
        
        public function Torus(
            innerRadius:Number, outerRadius:Number, sides:int = 16, rings:int = 16):void
        {
            _innerRadius = innerRadius;
            _outerRadius = outerRadius;
            _sides = sides;
            _rings = rings;
            
            build();
        }
        
        /**
         * @private
         */
        private function build():void
        {
            vertices = new Vector.<Vector3D>();
            indices = new Vector.<int>();
            uvtData = new Vector.<Number>();
            
            var i:int;
            var j:int;
            
            var a:Number = 0;
            var adda:Number = Math.PI * 2 / _sides;
            
            var b:Number = 0;
            var addb:Number = Math.PI * 2 / _rings;
            
            for (i = 0; i < _sides; i++, a += adda)
            {
                var ca:Number = Math.cos(a);
                var sa:Number = Math.sin(a);
                
                var s:Number = sa * _innerRadius + _outerRadius;
                var z:Number = ca * _innerRadius;
                
                for (j = 0; j < _rings; j++, b += addb)
                {
                    var cb:Number = Math.cos(b);
                    var sb:Number = Math.sin(b);
                    
                    vertices.push(new Vector3D(cb * s, sb * s, z));
                    uvtData.push(cb * (sa + 0.8) / 2 + 0.5, -sb * (sa + 0.8) / 2 + 0.5);
                }
            }
            
            var n:int = _sides * _rings;
            
            for (i = 0; i < _sides; i++)
            {
                var off:Number = i * _rings;
                
                for (j = 0; j < _rings; j++)
                {
                    var n1:int = int((off + _rings) % n + (j + 1) % _rings);
                    var n2:int = int( off               + (j + 1) % _rings);
                    var n3:int = int( off               +  j              );
                    var n4:int = int((off + _rings) % n +  j              );
                    
                    indices.push(n1, n2, n3,  n1, n3, n4);
                }
            }
        }
        
        public function get numPartitions():int
        {
            return _sides;
        }
        
        public function set numPartitions(value:int):void 
        {
            _sides = value;
            _rings = value;
            
            build();
        }
    }
}