root/as3/Astro/Torus3D_01/src/Document.as

package
{
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.display.TriangleCulling;
    import flash.events.Event;
    import flash.events.KeyboardEvent;
    import flash.geom.Matrix3D;
    import flash.geom.PerspectiveProjection;
    import flash.geom.Vector3D;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import net.unbland.debug.FPS;
    import primitives.Torus;
    
    [SWF(width=320, height=320, backgroundColor=0x000000, frameRate=30)]
    public class Document extends Sprite
    {
        private var canvas:Sprite = new Sprite();
        
        private var projection:PerspectiveProjection = new PerspectiveProjection();
        private var scene:Sprite = new Sprite();
        private var primitive:Torus = new Torus(20, 40);
        
        private var texture:BitmapData;
        
        [Embed(source = "images/texture.jpg")]
        private var image:Class;
        
        public function Document():void
        {
            setupStage();
            
            canvas.x = stage.stageWidth / 2;
            canvas.y = stage.stageHeight / 2;
            addChild(canvas);
            
            projection.fieldOfView = 60;
            
            scene.transform.matrix3D = new Matrix3D();
            scene.addEventListener(Event.ENTER_FRAME, renderScene);
            
            texture = Bitmap(new image()).bitmapData;
    }
        
        private function renderScene(e:Event):void 
        {
            var world:Matrix3D = scene.transform.matrix3D.clone();
            world.append(projection.toMatrix3D());
            
            var vertices:Vector.<Number> = new Vector.<Number>();
            var indices:Vector.<int> = new Vector.<int>();
            
            var i:int;
            var l:int;
            
            var temp:Vector.<Object> = new Vector.<Object>();
            
            for (i = 0, l = primitive.vertices.length; i < l; i++)
            {
                var vertex:Vector3D = primitive.vertices[i];
                var vector:Vector3D = world.transformVector(vertex);
                
                vector.w = projection.focalLength / (projection.focalLength + vector.z);
                vector.project();
                
                vertices.push(vector.x, vector.y);
                temp.push({z:vector.z, i:i});
            }
            
            var triangles:Array = [];
            
            for (i = 0, l = primitive.indices.length; i < l; i += 3)
            {
                var v1:Object = temp[primitive.indices[i    ]];
                var v2:Object = temp[primitive.indices[i + 1]];
                var v3:Object = temp[primitive.indices[i + 2]];
                
                triangles.push({
                    v1:v1,
                    v2:v2,
                    v3:v3,
                    z:(v1.z + v2.z + v3.z) / 3
                });
            }
            
            triangles.sortOn("z", Array.NUMERIC);
            
            for each (var triangle:Object in triangles)
            {
                indices.push(triangle.v1.i, triangle.v2.i, triangle.v3.i);
            }
            
            canvas.graphics.clear();
            canvas.graphics.beginBitmapFill(texture);
            canvas.graphics.drawTriangles(
                vertices, indices, primitive.uvtData, TriangleCulling.NEGATIVE
            );
            
            scene.rotationX += 2;
            scene.rotationY += 4;
            scene.rotationZ += 3;
        }
        
        private function setupStage():void
        {
            FPS.show(stage);
            
            stage.showDefaultContextMenu = false;
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            var numPartitions:int = primitive.numPartitions;
            
            var textField:TextField = new TextField();
            textField.background = true;
            textField.backgroundColor = 0x000000;
            textField.textColor = 0xFFFFFF;
            textField.autoSize = TextFieldAutoSize.LEFT;
            
            textField.text = "numPartitions : " + numPartitions + "\n" +
                             "numTriangles  : " + numPartitions * numPartitions;
            textField.x = stage.stageWidth - textField.width;
            textField.y = stage.stageHeight - textField.height;
            
            addChild(textField);
            
            stage.addEventListener(KeyboardEvent.KEY_DOWN, function(e:KeyboardEvent):void
            {
                switch (e.keyCode)
                {
                    case 37:
                    {
                        if (primitive.numPartitions <= 3)
                        {
                            primitive.numPartitions = 3;
                        }
                        else
                        {
                            primitive.numPartitions--;
                        }
                        break;
                    }
                    case 39:
                    {
                        primitive.numPartitions++;
                        break;
                    }
                }
                
                var numPartitions:int = primitive.numPartitions;
                
                textField.text = "numPartitions : " + numPartitions + "\n" +
                                 "numTriangles  : " + numPartitions * numPartitions;
                textField.x = stage.stageWidth - textField.width;
                textField.y = stage.stageHeight - textField.height;
            });
        }
    }
}