root/as3/Astro/ShaderFilter/RasterScroll/RasterScroll.as

package
{
        import flash.display.*;
        import flash.utils.*;
        import flash.events.*;
        import flash.filters.ShaderFilter;
        import flash.geom.*;

        public class RasterScroll extends Sprite
        {
                [Embed(source="shader/rasterscroll.pbj", mimeType="application/octet-stream")]
                private var ShaderBC:Class; // ByteArray

                [Embed(source="testimage.png", mimeType="image/png")]
                private var TestBmp:Class; // BitmapData

                private var mRSShader:Shader;
                private var mRSFilter:ShaderFilter;

                private var mCount:int;

                private var mOutBitmapData:BitmapData;
                private var mOutBitmap:Bitmap;
                private var mClearRect:Rectangle;

                private var mSrcBitmap:Bitmap;

                function RasterScroll()
                {
                        var bc:ByteArray = new ShaderBC();
                        mRSShader = new Shader(bc);

                        mRSFilter = new ShaderFilter();
                        mRSFilter.shader = mRSShader;
                        mRSShader.data.wavelen_y.value = [40];

                        mSrcBitmap = new TestBmp();

                        mOutBitmapData = new BitmapData(256, 256, true);
                        mClearRect  = new Rectangle(0, 0, 256, 256);
                        mOutBitmap = new Bitmap(mOutBitmapData);

                        addChild(mOutBitmap);
                        mCount = 30;
                        addEventListener(Event.ENTER_FRAME, onEnterFrame);
                        stage.addEventListener(MouseEvent.CLICK, onClick);
                }

                private function onClick(e:MouseEvent):void
                {
                        mCount = 30;
                        mRSShader.data.wavelen_y.value = [20 + mouseY];
                }

                private function onEnterFrame(e:Event):void
                {
                        if (mCount == 0)
                                return;

                        mCount--;

                        var shdata:ShaderData = mRSShader.data;
                        shdata.amp_x.value = [0];
                        shdata.amp_y.value = [mCount*2.0];
                        shdata.phase_y.value = [mCount * 0.3]

                        mOutBitmapData.fillRect(mClearRect, 0);
                        mOutBitmapData.applyFilter(mSrcBitmap.bitmapData, mClearRect, new Point(0,0), mRSFilter);
                }
        }
}