root/as3/Astro/ShaderFilter/Mudflow/Mudflow.as

package
{
        import flash.utils.*;
        import flash.display.*;
        import math2d.*;
        import phys.*;
        import flash.events.*;
        public class Mudflow extends Sprite
        {
                [Embed(source="mb.pbj", mimeType="application/octet-stream")]
                private var ShaderBC:Class; // ByteArray
                private var mMBShader:Shader;

                private var mMB:MetaBallCanvas;
                private var mTickcount:int = 0;
                private var mSCanvas:ScratchCanvas;
                private var mParticles:ParticleManager;
                private var mField:Field;

                function Mudflow()
                {
                        setupShader();
                        mField = new Field();

                        mMB = new MetaBallCanvas(320, 256, mMBShader);
                        mSCanvas = new ScratchCanvas(320, 256);
                        mParticles = new ParticleManager(128, mMB.offscreenSprite);

                        addChild(mMB);
                        addChild(mSCanvas);

                        createField();


                        mField.particles = mParticles;

                        addEventListener(Event.ENTER_FRAME, onEnterFrame);
                }

                private function setupShader():void
                {
                        var src:ByteArray = new ShaderBC();
                        mMBShader = new Shader(src);
                }

                private function createField():void
                {
                        var s:UShape = new UShape();
                        s.addPile(new Pile(-100, 50));
                        s.addPile(new Pile(150, 130));
                        s.addPile(new Pile(180, 160));
                        s.addPile(new Pile(180, 200));
                        s.addPile(new Pile(-100, 200));

                        s.close();
                        mField.addShape(s);
                        s.renderShape(mSCanvas, 0x666033);

                        s = new UShape();
                        s.addPile(new Pile(300, 180));
                        s.addPile(new Pile(300, 230));
                        s.addPile(new Pile(220, 230));
                        s.addPile(new Pile(220, 210));
                        s.addPile(new Pile(250, 190));

                        s.close();
                        mField.addShape(s);
                        s.renderShape(mSCanvas, 0x666033);
                }

                private function onEnterFrame(e:Event):void
                {
                        mField.updatePhys();
                        mField.updatePosition();
                        mField.render();

                        mMB.render();

                        var basex:int = mouseX;
                        if (basex < 10) basex = 10;
                        if (basex > 245) basex = 245;
                        if ((mTickcount++ % 3) == 0)
                        {
                                var p:PBall = mParticles.addBall(Math.random() * 30 + basex, -10);
                                if (p) p.v.y = 4;

                        }
                }
        }
}