root/as3/Astro/ShaderFilter/Mudflow/MetaBallCanvas.as

package
{
        import flash.display.*;
        import flash.geom.*;
        import flash.filters.ShaderFilter;

        public class MetaBallCanvas extends Sprite
        {
                private var mOfsSprite:Sprite;
                private var mOffscreen:BitmapData;

                private var mBitmapData:BitmapData;
                private var mBitmap:Bitmap;

                private var mClearRect:Rectangle;
                private var mFilter:ShaderFilter;

                function MetaBallCanvas(w:int, h:int, shader:Shader)
                {
                        shader.data.color.value  = [0.7,0.2,0.1,1];
                        shader.data.thresh.value = [0.38];

                        mFilter = new ShaderFilter();
                        mFilter.shader = shader;

                        mOfsSprite = new Sprite();
                        mOffscreen = new BitmapData(w, h, true, 0);
        
                        mBitmapData = new BitmapData(w, h, true, 0);
                        mBitmap = new Bitmap(mBitmapData);
                        mClearRect = new Rectangle(0, 0, w, h);

                        addChild(mBitmap);
                }

                public function get offscreenSprite():Sprite
                {
                        return mOfsSprite;
                }

                public function render():void
                {
                        mOffscreen.fillRect(mClearRect, 0);
                        mOffscreen.draw(mOfsSprite);
                        mBitmapData.applyFilter(mOffscreen, mClearRect, new Point(0,0), mFilter);
                }

        }
}