root/as3/Astro/ShaderFilter/CalcShader/src/CalcShader.as

package 
{
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Shader;
    import flash.display.Sprite;
    import flash.filters.ShaderFilter;
    import flash.geom.Point;
    import flash.utils.ByteArray;
    import net.unbland.debug.TimeMeasure;
    import net.unbland.debug.Tracer;
    
    [SWF(width=1024, height=1024, backgroundColor=0xFFFFFF, frameRate=30)]
    public class CalcShader extends Sprite
    {
        private static const SIZE:uint = 1024;
        
        [Embed(source="shaders/colorize.pbj", mimeType="application/octet-stream")]
        private var shaderData:Class;
        
        public function CalcShader():void
        {
            // 下準備 ------------------------------
            
            var array:Array = [];
            var vector:Vector.<uint> = new Vector.<uint>();
            
            for (var h:int = 0; h < SIZE; h++)
            {
                for (var w:int = 0; w < SIZE; w++)
                {
                    array.push(0xFF000000);
                    vector.push(0xFF000000);
                }
            }
            
            var src:BitmapData = new BitmapData(SIZE, SIZE);
            var dst:BitmapData = new BitmapData(SIZE, SIZE);
            
            var point:Point = new Point();
            var shader:Shader = new Shader(ByteArray(new shaderData()));
            var shaderFilter:ShaderFilter = new ShaderFilter(shader);
            
            var i:int;
            var l:int;
            
            // 計測開始 ------------------------------
            
            // Shader + Vector の計測
            Tracer.debug("Shader + Vector の計測を開始します。");
            TimeMeasure.begin();
            
            src.setVector(src.rect, vector);
            shader.data.color.value = [1, 0, 0, 0];
            dst.applyFilter(src, src.rect, point, shaderFilter);
            
            var ds:Vector.<uint> = dst.getVector(dst.rect);
            
            TimeMeasure.endAndTrace();
            
            // Vector の計測
            Tracer.debug("Vector の計測を開始します。");
            TimeMeasure.begin();
            
            for (i = 0, l = vector.length; i < l; i++)
            {
                vector[i] += 0x00FF0000;
            }
            
            var dv:Vector.<uint> = Vector.<uint>(vector.concat());
            
            TimeMeasure.endAndTrace();
            
            // Array の計測
            Tracer.debug("Array の計測を開始します。");
            TimeMeasure.begin();
            
            for (i = 0, l = array.length; i < l; i++)
            {
                array[i] += 0x00FF0000;
            }
            
            var da:Array = array.concat();
            
            TimeMeasure.endAndTrace();
            
            // 最後にテスト結果の確認
            l = SIZE * SIZE - 1;
            
            Tracer.debug(
                "最後にテストが正しいかの確認\n" +
                "0xFF000000 + 0x00FF0000 なので、結果は 0xFFFF0000 になる\n\n" +
                "Shader + Vector => 0x" + ds[l].toString(16).toUpperCase() + "\n" +
                "Vector => 0x" + dv[l].toString(16).toUpperCase() + "\n" +
                "Array => 0x" + da[l].toString(16).toUpperCase()
            );
            
            addChild(new Bitmap(dst));
        }
    }
}