root/as2/TeraClock/src/uranodai/utils/TeraClock.as

import mx.events.EventDispatcher;
import mx.utils.Delegate;
/**
* ...
* @author uranodai
*/

class uranodai.utils.TeraClock
{
        public static var HOURS_CHANGED:String = "hoursChanged";
        public static var MINUTES_CHANGED:String = "minutesChanged";
        public static var SECONDS_CHANGED:String = "secondsChanged";
        
        private var _hours:Number;
        private var _minutes:Number;
        private var _seconds:Number;
        private var _preSeconds:Number;
        private var _gmt:Number;
        
        public var addEventListener:Function;
    public var removeEventListener:Function;
    private var dispatchEvent:Function;
        
        // コンストラクタ関数。引数でタイムゾーンを設定できる。デフォルトは+9:00（日本）
        public function TeraClock(mc:MovieClip, GMT:Number) 
        {
                EventDispatcher.initialize(this);
                
                if (GMT == undefined) GMT = 9;  
                _gmt = GMT % 24;
                enterFrameListener();
                mc.onEnterFrame = Delegate.create(this, enterFrameListener);
        }
        
        public function enterFrameListener():Void
        {
                var date:Date = new Date();
                
                if(_gmt>=0){
                        _hours = (date.getUTCHours() + _gmt) % 24;
                }else {
                        _hours = (24+(date.getUTCHours() + _gmt)) % 24;
                }
                _minutes = date.getUTCMinutes();
                _seconds = date.getUTCSeconds();
                if (_seconds != _preSeconds) {
                        //trace(_hours + ":" + _minutes + ":" + _seconds);
                        dispatchEvent( { type:SECONDS_CHANGED } );
                        if (_seconds == 0) {
                                dispatchEvent( { type:MINUTES_CHANGED } );
                                if (_minutes == 0) {
                                        dispatchEvent( { type:HOURS_CHANGED } );
                                }
                        }
                }
                _preSeconds = _seconds;
                //trace(this);
        }
        
        // 外部から値を取得するためのゲッター。セッターはとりあえずいらないや。
        public function get hours():Number { return _hours; }
        public function get minutes():Number { return _minutes; }
        public function get seconds():Number { return _seconds; }
        // 上位1桁返す
        public function get hoursUpper():Number { return Math.floor(_hours / 10); }
        public function get minutesUpper():Number { return Math.floor(_minutes / 10); }
        public function get secondsUpper():Number { return Math.floor(_seconds / 10); }
        // 下位1桁返す
        public function get hoursLower():Number { return _hours % 10; }
        public function get minutesLower():Number  { return _minutes % 10; }
        public function get secondsLower():Number { return _seconds % 10; }
        // 1桁の数の時を2桁にする。返り値は String 型になる。
        public function get hours2():String { return niketa(_hours); }
        public function get minutes2():String { return niketa(_minutes); }
        public function get seconds2():String { return niketa(_seconds); }
        // 2桁にして返す関数
        private function niketa(num:Number):String {
                if (num < 10) {
                        return String("0"+num);
                }else {
                        return String(num);
                }
        }
        
        //アナログ時計にした時の針の角度を返す。
        public function get hoursDegree():Number {
                return ((_hours % 12) * 30) + (_minutes / 2) + (_seconds/120);
        }
        public function get minutesDegree():Number {
                return (_minutes * 6) + (_seconds / 10);
        }
        public function get secondsDegree():Number {
                return _seconds * 6;
        }
}