root/as2/SoundManager/src/jp/sygnas/sound/SEManager.as

/*
* Copyright 2007 dada
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
*     http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/

/*////////////////////////////////////////////////
* jp.sygnas.sound.SEManager
* 
* SE管理クラス
*
* @version              0.99
* @author               dada
* @url                  http://sygnas.jp/
*
* BGMと違い、SEは複数同時に呼び出すことがあるので、
* SE事にSoundオブジェクトを作成する。
* ライブラリからの呼び出しのみ対応。
* 全サウンドに対して Soundオブジェクトを作るので、大量登録には注意
*
* volumeプロパティによる音量変更は、全Soundオブジェクトに対して処理するので注意。
* 個別に音量調整するには setVolumeMax( name:String, vol:Number ) を用います
*
* ////////////////////////////////////////////////
* @usage
*       var mySE:SEManager = new SEManager(this);
*       mySE.addSE( "se1","se1.mp3",50 );
*       mySE.play( "bgm1" );
*
*/
import mx.utils.Delegate;

class jp.sygnas.sound.SEManager{

        public var _seList:Object;                              // Soundオブジェクトリスト

        private var $total:Number;                              // 全SE数
        private var $target:MovieClip;                  // 配置する場所
        private var $enabled:Boolean;                   // 再生が認められているか
        private var $gVolume:Number;                    // 全体の音量

        private var $onVolume:Function;                 // ボリュームが変更された
        private var $onError:Function;                  // 指定された曲がないなどのエラー
        private var $onEnabled:Function;                // 有効無効切り替え時
        
        
        /* /////////////////////////////////////////
        * プロパティ
        */
        
        /* 
        * 全体のボリューム
        * 0～100の範囲で与える。
        * 曲登録時の基準ボリュームを100として考える。
        * 50で登録した曲を、50で再生していたら「100」を返す。
        */
        public function get volume():Number{ return $gVolume; }
        public function set volume( vol:Number ){ ___setVolume( vol ); $onVolume( this ); }
        
        // 総曲数
        public function get total():Number{ return $total; }

        // 有効・無効
        public function get enabled():Boolean{ return $enabled; }
        public function set enabled( mode:Boolean ){ ___setEnabled( mode ); }

        // イベント
        public function set onError( func:Function ){ $onError = func; }
        public function set onEnabled( func:Function ){ $onError = func; }

        
        /* /////////////////////////////////////////
        * メソッド
        */
        
        /******************************
        * コストラクタ
        * target        soundオブジェクトを割り当てる場所
        * vol           スタート時のボリューム。指定がなければ「50」
        */
        public function SEManager( stage:MovieClip, vol:Number ){
                $target = stage;
                
                $total = 0;
                $gVolume = vol!=undefined ? vol : 50;
                $enabled = true;
                _seList = new Object();
        }
        
        /******************************
        * SEを追加
        * name                  音声識別子
        * link                  リンケージ名
        * vol                   ボリューム   
        * func                  再生終了時関数
        */
        public function addSE( name:String, link:String, vol:Number, func:Function ){
                _seList[name] = new Object();
                _seList[name]['sound'] = new Sound( $target );
                _seList[name]['sound'].attachSound( link )
                _seList[name]['sound'].onSoundComplete = func;
                _seList[name]['vol'] = vol;
                $total ++;
        }
        
        /******************************
        * 指定されたSEを再生
        */
        public function play( name:String ){
                if( !$enabled ) return;
                if( !___checkExists( name )) return;
                                                                   
                _seList[name]['sound'].start( name );
        }
        
        /******************************
        * 指定されたSEを停止
        */
        public function stop( name:String ){
                _seList[name]['sound'].stop();
        }
        
        /******************************
        * 最大音量を個別に設定
        * name                  音声識別子
        * vol                   音量
        */
        public function setVolumeMax( name:String, vol:Number ){
                _seList[name]['vol'] = Math.max( 0, Math.min( vol, 100 ));
                _seList[name]['sound'].setVolume( ___convRealVolume( _seList[name]['vol'] ));
        }
        
        /******************************
        * 最大音量を個別に取得
        * name                  音声識別子
        */
        public function getVolumeMax( name:String ):Number{
                return _seList[name]['vol'];
        }

        /******************************
        * SE再生完了時に実行する関数を個別に指定
        */
        public function setSoundComplete( name:String, func:Function ){
                _seList[name]['sound'].onSoundComplete = func;
        }
        
        /******************************
        * 破棄する
        */
        public function dispose(){
                for( var key:String in _seList ){
                        delete _seList[key]['sound'];
                        delete _seList[key];
                }
                delete _seList;
                delete this;
        }


        /* /////////////////////////////////////////
        * プライベートメソッド
        */

        /******************************
        * 音声が登録されているか
        */
        private function ___checkExists( name ){
                if( _seList[name] == undefined ){
                        $onError( this, "NO_ADDED" );
                        return false;
                }
                return true;
        }
        
        /******************************
        * 全体の音量を設定
        */
        private function ___setVolume( vol:Number ){
                $gVolume = vol;
                
                var seList:Object = _seList;
                
                for( var key:String in seList ){
                        seList[key]['sound'].setVolume( ___convRealVolume( seList[key]['vol'] ));
                }
        }
        /******************************
        * 実際のボリュームを計算
        */
        private function ___convRealVolume( titleVol:Number ):Number{
                return titleVol * $gVolume / 100;
        }
        
        /******************************
        * 有効無効切り替え
        * 無効なら曲を止める
        */
        private function ___setEnabled( mode:Boolean ){
                $enabled = mode;
                if( !mode ){
                        var seList:Object = _seList;
                        for( var key:String in seList ){
                                seList[key]['sound'].stop();
                        }
                }
                $onEnabled( this, $enabled );
        }
        
        
}