root/as2/SoundManager/src/jp/sygnas/sound/BGMManager.as

/*
* Copyright 2007 dada
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
*     http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/

/*////////////////////////////////////////////////
* jp.sygnas.sound.BGMManager
* 
* BGM管理クラス
*
* @version              0.99
* @author               dada
* @url                  http://sygnas.jp/
*
* ライブラリからの呼び出しおよび、外部MP3に対応。
* 外部MP3呼び出しの場合ストリーミングは行わない。
*
* ////////////////////////////////////////////////
* @usage
*       var myBGM:BGMManager = new BGMManager(this,100);
*       myBGM.addBGM( "bgm1","bgm1.mp3","LOAD",50 );
*       myBGM.fadein( "bgm1", 2 );
*
* ////////////////////////////////////////////////
* ■履歴
* 2007/11/01    ストリーミングパラメータ「_streaming:Boolean」を追加。
*                               ストリーミング再生時は fadein()、crossfade()をしてもフェードまでに再生が始まらない可能性があります。
*                               ストリーミング再生時は、ループ指定がききません。onSoundComplete を受け取って play() を実行してください。
*                               ストリーミング再生時は、即座にイベントonSoundPlay が呼び出されます。
*
* 2007/10/30    フェードイン時にもイベント「onSoundPlay」を発生するようにした。
*                               STOP時に pause() を実行すると、play() を実行するように変更。
*
*
* ////////////////////////////////////////////////
* ■イベント
* onSoundPlay( bgmManager:BGMManager )
*       再生開始した
*
* onSoundComplete( bgmManager:BGMManager )
*       再生完了した
*
* onSoundStop( bgmManager:BGMManager )
*       停止した
*
* onSoundPause( bgmManager:BGMManager, bool:Boolean )
*       一時停止した。「bool」は一時停止状態なら「true」、再生再開なら「false」
*
* onFadeInComp( bgmManager:BGMManager )
*       フェードイン完了
*
* onFadeOutComp( bgmManager:BGMManager )
*       フェードアウト完了
*
* onCrossFadeComp( bgmManager:BGMManager )
*       クロスフェード完了
*
* onVolume( bgmManager:BGMManager )
*       ボリュームが変わった
*
* onTitle( bgmManager:BGMManager )
*       再生する曲が変わった
*
* onError( bgmManager:BGMManager, msg:String )
*       エラー発生。メッセージは後述の「エラーについて」参照。     
*
* onEnabled( bgmManager:BGMManager, bool:Boolean )
*       再生の有効、無効が変わった
*       
*
* ////////////////////////////////////////////////
* ■エラーについて
* 再生失敗すると onError( obj:BGMManager, message:String ) を呼びます。
* LOAD_ERROR    外部MP3の読み込み失敗
* NO_ADDED              指定された識別子は登録されていない
* 
*/


import mx.utils.Delegate;

class jp.sygnas.sound.BGMManager{


        public static var INTERVAL:Number       = 50;           // フェードアウト時の間隔(ms)
        public static var VERSION:String        = "0.99";       // バージョン
        
        public var _sound1:Sound;                               // サウンドオブジェクト
        public var _sound2:Sound;                               // サウンドオブジェクト。クロスフェード用
        public var _loop:Number;                                // ループ回数
        public var _streaming:Boolean;                  // ストリーミング再生をする。
        
        private var $bgmList:Object;                    // 曲のファイル名リスト { 識別子:{file:ファイル名, type:種別, vol:ボリューム }
        private var $total:Number;                              // 全曲数
        private var $nowTitle:String;                   // 現在再生している曲の識別子
        private var $gVolume:Number;                    // 全体の音量
        private var $interval:Number;                   // インターバルID
        private var $mode:String;                               // モード。PLAY / STOP / FADE_IN / FADE_OUT / CROSS_FADE など
        private var $target:MovieClip;                  // 配置する場所
        private var $enabled:Boolean;                   // 再生が認められているか
        private var $pausePos:Number;                   // 一時停止した時間
        private var $targetVolume:Number;               // フェードイン時の目標音量
        private var $fadeVolume1:Number;                // フェード中のボリューム
        private var $fadeVolume2:Number;                // フェード中のボリューム。クロスフェード用
        private var $fade1:Number;                              // フェードイン・アウト時の増減値
        private var $fade2:Number;                              // フェードイン・アウト時の増減値。クロスフェード用

        // イベント
        private var $onSoundComplete:Function;  // 再生完了した
        private var $onSoundPlay:Function;              // 再生開始した
        private var $onSoundStop:Function;              // 停止した
        private var $onSoundPause:Function;             // 一時停止した
        private var $onFadeInComp:Function;             // フェードイン完了時
        private var $onFadeOutComp:Function;    // フェードアウト完了時
        private var $onCrossFadeComp:Function;  // フェードアウト完了時
        private var $onVolume:Function;                 // ボリュームが変更された
        private var $onTitle:Function;                  // 再生曲が変わった
        private var $onError:Function;                  // 指定された曲がないなどのエラー
        private var $onEnabled:Function;                // 有効無効切り替え時
        
        
        /* /////////////////////////////////////////
        * プロパティ
        */
        
        /* 
        * 全体のボリューム
        * 0～100の範囲で与える。
        * 曲登録時の基準ボリュームを100として考える。
        * 50で登録した曲を、50で再生していたら「100」を返す。
        */
        public function get volume():Number{ return $gVolume; }
        public function set volume( vol:Number ){ ___setVolume( vol ); $onVolume( this ); }
        /*
        * 現在のモード
        * PLAY                  再生中
        * STOP                  停止
        * PAUSE                 一時停止
        * FADE_IN               フェードイン
        * FADE_OUT              フェードアウト
        * CROSS_FADE    クロスフェード
        */
        public function get mode():String{ return $mode; }

        // 再生中の曲
        public function get title():String{ return $nowTitle; }
        
        // 総曲数
        public function get total():Number{ return $total; }

        // 有効・無効
        public function get enabled():Boolean{ return $enabled; }
        public function set enabled( mode:Boolean ){ ___setEnabled( mode ); }

        // イベント
        public function set onSoundComplete( func:Function ){ $onSoundComplete = func; } 
        public function set onSoundPlay( func:Function ){ $onSoundPlay = func; } 
        public function set onSoundStop( func:Function ){ $onSoundStop = func; } 
        public function set onSoundPause( func:Function ){ $onSoundPause = func; } 
        public function set onFadeInComp( func:Function ){ $onFadeInComp = func; } 
        public function set onFadeOutComp( func:Function ){ $onFadeOutComp = func; } 
        public function set onCrossFadeComp( func:Function ){ $onCrossFadeComp = func; } 
        public function set onVolume( func:Function ){ $onVolume = func; } 
        public function set onTitle( func:Function ){ $onTitle = func; }
        public function set onError( func:Function ){ $onError = func; }
        public function set onEnabled( func:Function ){ $onEnabled = func; }

        
        /* /////////////////////////////////////////
        * メソッド
        */
        
        /******************************
        * コストラクタ
        * target        soundオブジェクトを割り当てる場所
        * vol           スタート時のボリューム。指定がなければ「50」
        */
        public function BGMManager( target:MovieClip, vol:Number ){
                $target = target;
                $gVolume = vol ? vol : 50;

                $total = 0;
                $bgmList = new Object();
                $mode = "STOP";
                $nowTitle = "";
                $enabled = true;
                _loop = 99999;
                _streaming = false;

                _sound1 = ___soundInit();
                _sound2 = ___soundInit();
        }
        
        /******************************
        * 曲を追加
        * name          識別子
        * file          外部MP3ならURL、ライブラリならリンケージ名
        * type          外部MP3なら「LOAD」、ライブラリなら「LIB」
        * vol           基準ボリューム。指定がなければ「100」になる
        */
        public function addBGM( name:String, file:String, type:String, vol:Number ){
                $bgmList[name] = { file:file, type:type, vol:vol?vol:100 };
                $total ++;
        }
        
        /******************************
        * 指定された曲を再生
        * name          識別子
        */
        public function play( name:String ){
                if( !$enabled ) return;
                $mode = "PLAY";
                ___soundReady( name );
        }

        /******************************
        * 曲を停止
        */
        public function stop(){
                if( $mode=="STOP" ) return;
                clearInterval( $interval );
                $mode = "STOP";
                _sound1.stop();
                $onSoundStop( this );
        }
        
        /******************************
        * 曲を一時停止
        */
        public function pause(){
                if( !$enabled ) return;
                
                if( $mode == "STOP" ){
                        this.play( $nowTitle );
                }else{
                        ___pause();
                }
        }
        
        /******************************
        * フェードイン
        * name          曲識別子
        * sec           フェードインにかける時間（秒）
        */
        public function fadein( name:String, sec:Number ){
                if( !$enabled ){ return; }
                $mode = "FADE_IN";
                ___fadeReady( sec, name );
        }
        
        /******************************
        * フェードアウト
        * sec           フェードアウトにかける時間（秒）
        */
        public function fadeout( sec:Number ){
                $mode = "FADE_OUT";
                ___fadeReady( sec );
        }

        /******************************
        * クロスフェード
        * name          曲識別子
        * sec           クロスフェードにかける時間（秒）
        */
        public function crossfade( name:String, sec:Number ){
                if( !$enabled ){ return; }
                $mode = "CROSS_FADE";
                ___fadeReady( sec, name );
        }
        
        /******************************
        * 曲単体の最大音量を変更
        * 演奏中の音量は変わらない
        * mame          曲識別子
        * vol           音量（0-100）
        */
        public function setVolumeMax( name:String, vol:Number ){
                $bgmList[name]['vol'] = Math.max( 0, Math.min( vol, 100 ));
        }
        
        /******************************
        * 曲単体の最大音量を取得
        * 演奏中の音量は変わらない
        * mame          曲識別子
        * vol           音量（0-100）
        */
        public function getVolumeMax( name:String ):Number{
                return $bgmList[name]['vol'];
        }
        
        /******************************
        * 破棄する
        */
        public function dispose(){
                delete _sound1;
                if( _sound2 ) delete _sound2;
                delete $bgmList;
                delete this;
        }
        
        
        /* /////////////////////////////////////////
        * プライベートメソッド
        */

        
        
        
        /******************************
        * フェードインアウトの準備
        */
        private function ___fadeReady( sec:Number, name:String ){
                // 登録されていなければエラー
                if( $mode=="FADE_IN" || $mode=="CROSS_FADE" ){
                        if( !___checkExists(name) ) return;
                }
                
                clearInterval( $interval );
                
                // 指定秒数かかるまでの回数と、１回あたりの調音率
                var titleVol:Number;
                var step:Number = sec * 1000 / INTERVAL;
                name = name ? name : $nowTitle;

                switch( mode ){
                        case "FADE_IN":
                                titleVol = $bgmList[name]['vol'];
                                $targetVolume = ___convRealVolume(titleVol);
                                $fade1 = $targetVolume / step;
                                $fadeVolume1 = 0;
                                break;
                                
                        case "FADE_OUT":
                                $fade1 = _sound1.getVolume() / step * -1;
                                $fadeVolume1 = _sound1.getVolume();
                                break;
                                
                        case "CROSS_FADE":
                                // 現在再生しているものを sound2。これから再生するものを sound1 にする
                                var tmp:Sound = _sound2;
                                _sound2 = _sound1;
                                _sound1 = tmp;
                                
                                titleVol = $bgmList[name]['vol'];
                                $targetVolume = ___convRealVolume(titleVol);
                                $fade1 = $targetVolume / step;
                                $fade2 = _sound2.getVolume() / step * -1;
                                $fadeVolume1 = 0;
                                $fadeVolume2 = _sound2.getVolume();
                                break;
                }

                if( $mode == "FADE_OUT" ){
                        $interval = setInterval( this, "___fadeInOut", INTERVAL );
                }else{
                        ___soundReady( name );
                }
        }

        /******************************
        * 指定された曲の再生準備
        */
        private function ___soundReady( name:String ){
                // 登録されていなければエラー
                if( !___checkExists(name) ) return;
                
                var type:String = $bgmList[name]['type'];
                var file:String = $bgmList[name]['file'];
        
                clearInterval( $interval );
                $nowTitle = name;
                $onTitle( this );
                
                if( type == "LOAD" ){
                        // ストリーミング指定されていたらすぐ再生に
                        _sound1.loadSound( file, _streaming );
                        if( _streaming ) ___startSound();
                }else{
                        _sound1.attachSound( file );
                        ___startSound();
                }
        }
        
        /******************************
        * サウンド読み込み完了したら再生
        */
        private function ___loadSound( success:Boolean ){
                trace("___loadSound");
                if(success){
                        if( !_streaming ) ___startSound();
                }else{
                        $mode = "STOP";
                        $onError( this, "LOAD_ERROR" );
                }
        }

        /******************************
        * 再生開始
        * pos           再生開始時間
        */
        private function ___startSound( pos:Number ){
                pos = pos ? pos : 0;
                _sound1.start(pos,_loop);
                
                // フェードインが設定されている場合はインターバルでボリューム上げていく
                if( $mode=="FADE_IN" || $mode=="CROSS_FADE"){
                        _sound1.setVolume(0);
                        $interval = setInterval( this, "___fadeInOut", INTERVAL );
                        $onSoundPlay( this );
                }else{
                        ___setVolume( $gVolume );       // ボリュームを再設定
                        $onSoundPlay( this );
                }
        }
        
        /******************************
        * フェードイン・アウトの調音
        */
        private function ___fadeInOut(){
                // ボリューム変更
                $fadeVolume1 += $fade1;
                $fadeVolume2 += $fade2;
                _sound1.setVolume( $fadeVolume1 );
                _sound2.setVolume( $fadeVolume2 );
                
                switch( $mode ){
                        case "FADE_IN":
                                if( $fadeVolume1 >= $targetVolume ){
                                        clearInterval( $interval );
                                        $mode = "PLAY";
                                        _sound1.setVolume( $targetVolume );
                                        $onFadeInComp( this );
                                }
                                break;
                        case "FADE_OUT":
                                if( $fadeVolume1 <= 0 ){
                                        clearInterval( $interval );
                                        $mode = "STOP";
                                        _sound1.stop();
                                        $onFadeOutComp( this );
                                }
                                break;
                        case "CROSS_FADE":
                                if( $fadeVolume1 >= $targetVolume ){
                                        clearInterval( $interval );
                                        $mode = "PLAY";
                                        _sound1.setVolume( $targetVolume );
                                        _sound2.stop();
                                        $onCrossFadeComp( this );
                                }
                                break;
                }
        }
        /******************************
        * 一時停止
        */
        private function ___pause(){
                clearInterval( $interval );
                
                if( $mode == "PAUSE" ){
                        $mode = "PLAY";
                        $onSoundPause( this, false );
                        ___startSound( $pausePos );
                }else{
                        $mode = "PAUSE";
                        $pausePos = _sound1.position /1000;     // 時間を記録しておく
                        _sound1.stop();
                        $onSoundPause( this, true );
                }
        }

        /******************************
        * ボリューム設定
        */
        private function ___setVolume( vol:Number ){
                $gVolume = vol;

                if( vol == 0 ){
                        _sound1.setVolume( 0 );
                }else if( $nowTitle ){
                        // 再生中の曲があれば、曲の基準ボリュームから実際のボリュームを設定
                        var titlevol:Number = $bgmList[$nowTitle]['vol'];
                        _sound1.setVolume( ___convRealVolume(titlevol) );
                }
        }
        /******************************
        * 実際のボリュームを計算
        */
        private function ___convRealVolume( titleVol:Number ):Number{
                return titleVol * $gVolume / 100;
        }
        
        /******************************
        * 有効無効切り替え
        * 無効なら曲を止める
        */
        private function ___setEnabled( mode:Boolean ){
                $enabled = mode;
                if( !mode ) _sound1.stop();
                $onEnabled( this, $enabled );
        }
        
        /******************************
        * 曲が登録されているか
        */
        private function ___checkExists( name ){
                if( $bgmList[name] == undefined ){
                        $onError( this, "NO_ADDED" );
                        $mode = "STOP";
                        return false;
                }
                return true;
        }

        /******************************
        * Soundオブジェクト初期化
        */
        private function ___soundInit():Sound{
                var sound:Sound = new Sound( $target );
                sound.setVolume( $gVolume );
                sound.onSoundComplete = Delegate.create( this, ___onSoundComplete );
                sound.onLoad = Delegate.create( this, ___loadSound );
                return sound;
        }

        /******************************
        * 再生完了
        */
        private function ___onSoundComplete(){
                $onSoundComplete( this );
        }
}