root/air/ByteCodeDisassembler/Controller.as

package{
    import flash.errors.EOFError;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.net.URLRequest;
    import flash.net.URLStream;
    
    import flash.utils.ByteArray;
    import org.libspark.disassemble.SwfStream;
    import org.libspark.disassemble.ByteStream;
    import org.libspark.disassemble.abc.ClassPrinter;
    import flash.events.*;
    public class Controller extends EventDispatcher {
        // listener用の定数
        static public var LOAD : String = 'LOAD';
        static public var INFO : String = 'INFO';

        private var frame_ : Array  = [];
        private var info_  : Object;

        private var stream : URLStream;

        public function get frame():Array{
            return frame_;
        }

        public function get info():Object{
            return info_;
        }
        
        
        // リスナの呼び出し
        private function notify(type : String):void{
            this.dispatchEvent(new Event(type));
        }

        /**
         * SWFの逆アセンブル。
         */
        public function disassemble(path : String) : void{
            this.reset();
            stream = new URLStream();
            stream.addEventListener(Event.COMPLETE, onComplete);

            var req:URLRequest = new URLRequest(path);
            stream.load(req);
        }

        private function onComplete(e : Event) : void {
            var bytes:ByteArray = new ByteArray();
            stream.readBytes(bytes);
            stream.close();

            var swf:SwfStream = new SwfStream(bytes);
            swf.seekToBody();
            try {
                for (;;) {
                    this.dispatchEvent(new ProgressEvent(ProgressEvent.PROGRESS,
                                                         false,false,
                                                         swf.position,swf.length));

                    var byte:uint = swf.readShort();
                    var tag:uint = byte >>> 6;
                    var length:uint = byte & 0x3f;
                    if (length == 0x3f) {
                        length = swf.readInt();
                    }
                    switch (tag) {
                    case 82: 
                        var tagStart:uint = swf.position;
                        swf.readUnsignedInt();
                        for (; swf.readByte() != 0x00; ) {}
                        var abcBytes:ByteArray = new ByteArray();
                        swf.readBytes(abcBytes, 0, length - (swf.position - tagStart));
                        frame_.push({label:'abc',tag:'abc',data: new ClassPrinter(abcBytes).parse()});
                        swf.seek(length);
                        break;
                        
                    default:
                        frame_.push({label:'???',tag:tag,length:length});
                        swf.seek(length);
                        break;
                    }
                }
            }catch (e:VerifyError) {
                trace(e.getStackTrace());
            }catch (e:EOFError) {
                trace(e);
            }
            this.notify(LOAD);
        }

        private function reset():void{
            this.frame_ = [];
        }

        public function showInfo(item : Object):void{
            this.info_ = item;
            this.notify(INFO);
        }
    }
}