root/air/AS3UnitGUI/dev/AS3UnitGUI.mxml

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication
        xmlns:mx="http://www.adobe.com/2006/mxml"
        xmlns:as3unit="org.libspark.as3unit.components.*"
        layout="absolute"
        title="AS3UnitGUI"
        applicationComplete="applicationCompleteHandler()">
    <mx:Script>
        <![CDATA[
            import mx.controls.Alert;
            import mx.events.FileEvent;
            import flash.filesystem.*;
            
            private var so:SharedObject;
            private var defaultFile:File;
            private var source:File;
            private var testSwf:Loader;
            private var testClass:Class;
            
            private function applicationCompleteHandler():void
            {
                var soData:Object;
                
                try {
                    so = SharedObject.getLocal("AS3UnitGUI");
                    soData = so.data;
                }
                catch (e:Error) {
                    so = null;
                    soData = new Object();
                }
                
                if ('swfPath' in soData) {
                    swfPathField.text = soData.swfPath;
                }
                if ('className' in soData) {
                    classNameField.text = soData.className;
                }
                
                defaultFile = File.documentsDirectory.resolve("as3unit");
                updateRunButtonEnabled();
                
                source = defaultFile.parent;
                source.addEventListener(Event.SELECT, fileSelectedHandler);
                
                if ('reload' in soData) {
                    reloadCheck.selected = soData.reload;
                }
                
                var window:NativeWindow = stage.window;
                window.width = 'w' in soData ? soData.w : 500;
                window.height = 'h' in soData ? soData.h : 550;
                if ('x' in soData) {
                    window.x = soData.x;
                }
                if ('y' in soData) {
                    window.y = soData.y;
                }
                window.addEventListener(NativeWindowBoundsEvent.MOVE, windowMoveHandler);
                window.addEventListener(NativeWindowBoundsEvent.RESIZE, windowResizeHandler);
                window.addEventListener(Event.CLOSE, windowCloseHandler);
                window.visible = true;
            }
            
            private function windowMoveHandler(event:Event):void
            {
                if (so) {
                    so.data.x = stage.window.x;
                    so.data.y = stage.window.y;
                }
            }
            
            private function windowResizeHandler(event:Event):void
            {
               if (so) {
                   so.data.w = stage.window.width;
                   so.data.h = stage.window.height; 
               }
            }
            
            private function windowCloseHandler(event:Event):void
            {
                if (so) {
                    so.flush();
                }
            }
            
            private function reloadCheckClickHandler():void
            {
                if (so) {
                    so.data.reload = reloadCheck.selected;
                }
            }
            
            private function selectFile():void
            {
                if (swfPathField.text.length > 0) {
                    source.nativePath = swfPathField.text;
                    source = source.parent;
                }
                if (!source || !source.exists || !source.isDirectory) {
                    source = defaultFile.parent;
                }
                source.browseForOpen("SWF Selection", [new FileFilter("SWF (*.swf)", "*.swf")]);
            }
            
            private function fileSelectedHandler(event:Event):void
            {
                swfPathField.text = source.nativePath;
            }
            
            private function swfPathFieldChangeHandler():void
            {
                testSwf = null;
                updateRunButtonEnabled();
                if (so) {
                    so.data.swfPath = swfPathField.text;
                }
            }
            
            private function classNameFieldChangeHandler():void
            {
                testClass = null;
                updateRunButtonEnabled();
                if (so) {
                    so.data.className = classNameField.text;
                }
            }
            
            private function updateRunButtonEnabled():void
            {
                runButton.enabled = swfPathField.text.length > 0 && classNameField.text.length > 0;
            }
            
            private function runButtonClickHandler():void
            {
                if (!testSwf || reloadCheck.selected) {
                    var stream:FileStream = new FileStream();
                    var swfFile:File = new File(swfPathField.text);
                    testSwf = new Loader();
                    testSwf.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, swfLoadIOErrorHandler);
                    testSwf.contentLoaderInfo.addEventListener(Event.COMPLETE, swfLoadCompleteHandler);
                    try {
                        stream.open(swfFile, FileMode.READ);
                        var bytes:ByteArray = new ByteArray();
                        stream.readBytes(bytes);
                        testSwf.loadBytes(bytes);
                    }
                    catch (e:IOError) {
                        Alert.show("Cat not load SWF file.");
                    }
                    finally {
                        stream.close();
                    }
                }
                else if (testClass) {
                    runTests(testClass);
                }
            }
            
            private function resetSwfHandler(dispatcher:EventDispatcher):void
            {
                dispatcher.removeEventListener(IOErrorEvent.IO_ERROR, swfLoadIOErrorHandler);
                dispatcher.removeEventListener(Event.COMPLETE, swfLoadCompleteHandler);
            }
            
            private function swfLoadIOErrorHandler(event:Event):void
            {
                resetSwfHandler(testSwf.contentLoaderInfo);
                Alert.show("Can not load SWF file.");
            }
            
            private function swfLoadCompleteHandler(event:Event):void
            {
                resetSwfHandler(testSwf.contentLoaderInfo);
                
                var appDomain:ApplicationDomain = testSwf.contentLoaderInfo.applicationDomain;
                var className:String = classNameField.text;
                
                if (!appDomain.hasDefinition(className)) {
                    Alert.show("Class<" + className + "> was not found in swf.");
                    return;
                }
                
                var clazz:Class = appDomain.getDefinition(className) as Class;
                if (!clazz) {
                    Alert.show("Definition<" + className + "> is not Class.");
                    return;
                }
                
                testClass = clazz;
                runTests(clazz);
            }
            
            private function runTests(testClass:Class):void
            {
                as3unit.run(testClass);
            }
        ]]>
    </mx:Script>
    <mx:VBox width="100%" height="100%"
                paddingBottom="10" paddingLeft="10"
                paddingRight="10" paddingTop="10">
                <mx:Label text="SWF file that contains test classes:"/>
                <mx:HBox width="100%">
                        <mx:TextInput id="swfPathField" width="100%" change="swfPathFieldChangeHandler()"/>
                        <mx:Button id="swfSelectButton" label="Select..." click="selectFile()"/>
                </mx:HBox>
                
                <mx:Label text="Test class name:"/>
                <mx:HBox width="100%">
                        <mx:TextInput id="classNameField" width="90%" change="classNameFieldChangeHandler()"/>
                        <mx:Button id="runButton" label="Run" click="runButtonClickHandler()"/>
                </mx:HBox>
                
                <mx:CheckBox id="reloadCheck" label="Reload classes every run" selected="true"
                    click="reloadCheckClickHandler()"/>
                
                <as3unit:AS3Unit id="as3unit"/>
    </mx:VBox>
</mx:WindowedApplication>