root/Mk-10/as2/src/jp/cellfusion/commands/LoaderCommand.as

/*
 * Copyright(c) 2007 Mk-10 cellfusion.jp
 * 
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND,
 * either express or implied. See the License for the specific language
 * governing permissions and limitations under the License.
 */

import jp.cellfusion.commands.CommandBase;

/**
 * @author Makoto Matsutake
 */
class jp.cellfusion.commands.LoaderCommand extends CommandBase {
        private var mcl:MovieClipLoader, url:String, path:Object;
        
        /**
         * @param       url 読み込むURL
         * @param       path 読み込み先
         */
        public function LoaderCommand(url:String, path:Object) {
                super();
                
                if (url == "" || url == null) throw new Error("urlが空です。");
                else this.url = url;
                
                if (path == "" || path == null) throw new Error("pathが空です。");
                else this.path = path;
                
                mcl = new MovieClipLoader();
                mcl.addListener(this);
        }
        
        /**
         * 実行
         */
        public function execute():Boolean {
                mcl.loadClip(url, path);
                
                return true;
        }
        
        /**
         * クローン
         */
        public function clone():LoaderCommand {
                return new LoaderCommand(url, path);
        }
        
        
        private function onLoadStart(target:MovieClip):Void {
                dispatchEvent({type:COMMAND_START, target:target, url:url});
        }
        
        private function onLoadProgress(target:MovieClip, loaded:Number, total:Number):Void {
                dispatchEvent({type:COMMAND_PROGRESS, target:target, loaded:loaded, total:total, url:url});
        }
        
        private function onLoadComplete(target:MovieClip):Void {
        }
        
        private function onLoadInit(target:MovieClip):Void {
                dispatchEvent({type:COMMAND_COMPLETE, target:target, url:url});
        }
        
        private function onLoadError():Void {
                trace("error");
        }
}